Fix bug where OpenAFS hangs (see #215550)

(Portage version: 2.1.4.4)

1 files changed, 60 insertions, 0 deletions

diff --git a/net-fs/openafs-kernel/openafs-kernel-1.4.7_pre2-r1.ebuild b/net-fs/openafs-kernel/openafs-kernel-1.4.7_pre2-r1.ebuild
new file mode 100644
index 000000000000..461cb07230f7
--- /dev/null
+++ b/net-fs/openafs-kernel/openafs-kernel-1.4.7_pre2-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs-kernel/openafs-kernel-1.4.7_pre2-r1.ebuild,v 1.1 2008/04/04 12:17:27 stefaan Exp $
+
+inherit eutils linux-mod versionator toolchain-funcs
+
+PATCHVER=0.14
+MY_PN=${PN/-kernel}
+MY_PV=${PV/_pre/pre}
+MY_P=${MY_PN}-${MY_PV}
+S=${WORKDIR}/${MY_P}
+DESCRIPTION="The OpenAFS distributed file system kernel module"
+HOMEPAGE="http://www.openafs.org/"
+SRC_URI="http://openafs.org/dl/candidate/${MY_PV}/${MY_P}-src.tar.bz2
+	mirror://gentoo/${MY_PN}-gentoo-${PATCHVER}.tar.bz2"
+
+LICENSE="IBM openafs-krb5 openafs-krb5-a APSL-2 sun-rpc"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+PATCHDIR=${WORKDIR}/gentoo/patches/$(get_version_component_range 1-2)
+
+CONFIG_CHECK="!DEBUG_RODATA ~!AFS_FS"
+ERROR_DEBUG_RODATA="OpenAFS is incompatible with linux' CONFIG_DEBUG_RODATA option"
+ERROR_AFS_FS="OpenAFS conflicts with the in-kernel AFS-support.  Make sure not to load both at the same time!"
+
+pkg_setup() {
+	linux-mod_pkg_setup
+}
+
+src_unpack() {
+	unpack ${MY_P}-src.tar.bz2
+	unpack ${MY_PN}-gentoo-${PATCHVER}.tar.bz2
+	cd "${S}"
+
+	EPATCH_SUFFIX="patch" epatch ${PATCHDIR}
+
+	# patch mistake in plain _pre2
+	epatch "${FILESDIR}"/STABLE14-linux-flush-unlock-20080402
+	epatch "${FILESDIR}"/STABLE14-linux-flush-compare-20080402
+
+	./regen.sh || die "Failed: regenerating configure script"
+}
+
+src_compile() {
+	ARCH="$(tc-arch-kernel)" econf --with-linux-kernel-headers=${KV_OUT_DIR} || die "Failed: econf"
+
+	ARCH="$(tc-arch-kernel)" emake -j1 only_libafs || die "Failed: emake"
+}
+
+src_install() {
+	MOD_SRCDIR=$(expr ${S}/src/libafs/MODLOAD-*)
+	[ -f ${MOD_SRCDIR}/libafs.${KV_OBJ} ] \
+			|| die "Couldn't find compiled kernel module"
+
+	MODULE_NAMES='libafs(fs/openafs:$MOD_SRCDIR)'
+
+	linux-mod_src_install
+}