Version bump.

(Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key A792A613)

2 files changed, 79 insertions, 1 deletions

diff --git a/net-ftp/lftp/ChangeLog b/net-ftp/lftp/ChangeLog
index 7e541a938215..9a37ffbcf01c 100644
--- a/net-ftp/lftp/ChangeLog
+++ b/net-ftp/lftp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-ftp/lftp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.409 2013/05/23 15:11:15 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.410 2013/05/29 14:27:41 jer Exp $
+
+*lftp-4.4.8 (29 May 2013)
+
+  29 May 2013; Jeroen Roovers <jer@gentoo.org> +lftp-4.4.8.ebuild:
+  Version bump.
 
 *lftp-4.4.7 (23 May 2013)
 
diff --git a/net-ftp/lftp/lftp-4.4.8.ebuild b/net-ftp/lftp/lftp-4.4.8.ebuild
new file mode 100644
index 000000000000..b4797c84e318
--- /dev/null
+++ b/net-ftp/lftp/lftp-4.4.8.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/lftp-4.4.8.ebuild,v 1.1 2013/05/29 14:27:41 jer Exp $
+
+EAPI=5
+inherit autotools eutils libtool
+
+DESCRIPTION="A sophisticated ftp/sftp/http/https/torrent client and file transfer program"
+HOMEPAGE="http://lftp.yar.ru/"
+SRC_URI="ftp://ftp.yars.free.net/pub/source/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+
+IUSE="+gnutls nls openssl socks5 +ssl"
+LFTP_LINGUAS=( cs de es fr it ja ko pl pt_BR ru zh_CN zh_HK zh_TW )
+IUSE+=" ${LFTP_LINGUAS[@]/#/linguas_}"
+
+REQUIRED_USE="
+	ssl? ( ^^ ( openssl gnutls ) )
+"
+
+RDEPEND="
+	>=sys-libs/ncurses-5.1
+	>=sys-libs/readline-5.1
+	dev-libs/expat
+	sys-libs/zlib
+	socks5? (
+		>=net-proxy/dante-1.1.12
+		virtual/pam
+	)
+	ssl? (
+		gnutls? ( >=net-libs/gnutls-1.2.3 )
+		openssl? ( >=dev-libs/openssl-0.9.6 )
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+	=sys-devel/libtool-2*
+	app-arch/xz-utils
+	dev-lang/perl
+	nls? ( sys-devel/gettext )
+	virtual/pkgconfig
+"
+
+DOCS=(
+	BUGS ChangeLog FAQ FEATURES MIRRORS NEWS README README.debug-levels
+	README.dnssec README.modules THANKS TODO
+)
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}/${PN}-4.0.2.91-lafile.patch" \
+		"${FILESDIR}/${PN}-4.3.5-autopoint.patch" \
+		"${FILESDIR}/${PN}-4.3.8-gets.patch"
+	sed -i configure.ac -e 's|^AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' || die
+	eautoreconf
+	elibtoolize # for Darwin bundles
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_with gnutls) \
+		$(use_with openssl openssl "${EPREFIX}"/usr) \
+		$(use_with socks5 socksdante "${EPREFIX}"/usr) \
+		--enable-packager-mode \
+		--sysconfdir="${EPREFIX}"/etc/${PN} \
+		--with-modules \
+		--without-included-regex
+}