Fixed library soname, added possibility to build with bluetooth support (dropped m68k mips s390 sparc-fbsd x86-fbsd). Removed unused.

(Portage version: 2.2_rc14/cvs/Linux 2.6.26-openvz.git-35f41f1 i686)

1 files changed, 54 insertions, 0 deletions

diff --git a/net-libs/libpcap/libpcap-1.0.0-r1.ebuild b/net-libs/libpcap/libpcap-1.0.0-r1.ebuild
new file mode 100644
index 000000000000..c209c005f8e8
--- /dev/null
+++ b/net-libs/libpcap/libpcap-1.0.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libpcap/libpcap-1.0.0-r1.ebuild,v 1.1 2008/11/16 15:07:50 pva Exp $
+
+inherit autotools eutils multilib toolchain-funcs
+
+DESCRIPTION="A system-independent library for user-level network packet capture"
+HOMEPAGE="http://www.tcpdump.org/"
+SRC_URI="http://www.tcpdump.org/release/${P}.tar.gz
+	http://www.jp.tcpdump.org/release/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+IUSE="ipv6 bluetooth"
+
+RDEPEND="!virtual/libpcap
+	bluetooth? ( net-wireless/bluez-libs )"
+DEPEND="${RDEPEND}
+	sys-devel/flex"
+PROVIDE="virtual/libpcap"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}/${P}-cross-linux.patch"
+	epatch "${FILESDIR}/${P}-install-bindir.patch"
+	epatch "${FILESDIR}/${P}-install-headers.patch"
+	epatch "${FILESDIR}/${P}-optional-bluetooth.patch"
+	epatch "${FILESDIR}/${P}-LDFLAGS.patch"
+	eautoreconf
+}
+
+src_compile() {
+	econf $(use_enable ipv6) \
+		$(use_enable bluetooth)
+	emake all shared || die "compile problem"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-shared || die "emake install failed"
+
+	dosym libpcap.so.${PV:0:5} /usr/$(get_libdir)/libpcap.so.1
+	dosym libpcap.so.${PV:0:5} /usr/$(get_libdir)/libpcap.so
+
+	# We need this to build pppd on G/FBSD systems
+	if [[ "${USERLAND}" == "BSD" ]]; then
+		insinto /usr/include
+		doins pcap-int.h || die "failed to install pcap-int.h"
+	fi
+
+	# We are not installing README.{Win32,aix,hpux,tru64} (bug 183057)
+	dodoc CREDITS CHANGES VERSION TODO README{,.dag,.linux,.macosx,.septel}
+}