version bump as per bug #231610 thanks to Arfrever Frehtes Taifersar Arahesis

(Portage version: 2.2_rc1/cvs/Linux 2.6.22-vs2.2.0.7-gentoo x86_64)

2 files changed, 81 insertions, 1 deletions

diff --git a/net-libs/gnutls/ChangeLog b/net-libs/gnutls/ChangeLog
index d9911cd29b9d..34a6ed77a364 100644
--- a/net-libs/gnutls/ChangeLog
+++ b/net-libs/gnutls/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/gnutls
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.159 2008/07/01 12:38:39 dragonheart Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.160 2008/08/17 06:31:03 dragonheart Exp $
+
+*gnutls-2.5.3 (17 Aug 2008)
+
+  17 Aug 2008; Daniel Black <dragonheart@gentoo.org> +gnutls-2.5.3.ebuild:
+  version bump as per bug #231610 thanks to Arfrever Frehtes Taifersar Arahesis
 
 *gnutls-2.4.1 (01 Jul 2008)
 
diff --git a/net-libs/gnutls/gnutls-2.5.3.ebuild b/net-libs/gnutls/gnutls-2.5.3.ebuild
new file mode 100644
index 000000000000..375dfc4bc7b7
--- /dev/null
+++ b/net-libs/gnutls/gnutls-2.5.3.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-2.5.3.ebuild,v 1.1 2008/08/17 06:31:03 dragonheart Exp $
+
+inherit libtool autotools eutils
+
+DESCRIPTION="A TLS 1.0 and SSL 3.0 implementation for the GNU project"
+HOMEPAGE="http://www.gnutls.org/"
+SRC_URI="http://www.gnu.org/software/gnutls/releases/${P}.tar.bz2"
+#SRC_URI="mirror://gnu/gnutls/${P}.tar.bz2"
+
+# GPL-3 for the gnutls-extras library and LGPL for the gnutls library.
+LICENSE="LGPL-2.1 GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="zlib lzo doc nls guile bindist"
+
+RDEPEND="dev-libs/libgpg-error
+	>=dev-libs/libgcrypt-1.2.4
+	>=dev-libs/libtasn1-0.3.4
+	nls? ( virtual/libintl )
+	guile? ( dev-scheme/guile )
+	zlib? ( >=sys-libs/zlib-1.1 )
+	!bindist? ( lzo? ( >=dev-libs/lzo-2 ) )"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	if use guile && ! built_with_use dev-scheme/guile networking; then
+		eerror "You are trying to compile ${PN} package with USE=\"guile\""
+		eerror "while dev-scheme/guile does not have USE=\"networking\""
+		die
+	fi
+	if use lzo && use bindist; then
+		ewarn "lzo support was disabled for binary distribution of gnutls"
+		ewarn "due to licensing issues. See Bug 202381 for details."
+		epause 5
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${PN}-2.3.11+gcc-4.3.patch
+
+	elibtoolize # for sane .so versioning on FreeBSD
+}
+
+src_compile() {
+	local myconf
+	use bindist && myconf="--without-lzo" || myconf="$(use_with lzo)"
+	econf  \
+		$(use_with zlib) \
+		$(use_enable nls) \
+		$(use_enable guile) \
+		$(use_enable doc gtk-doc) \
+		${myconf}
+	emake || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog NEWS \
+		README THANKS doc/TODO
+
+	if use doc ; then
+		dodoc doc/README.autoconf doc/tex/gnutls.ps
+		docinto examples
+		dodoc doc/examples/*.c
+	fi
+}