Add another snapshot.

(Portage version: 2.2.0_alpha188/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

3 files changed, 109 insertions, 3 deletions

diff --git a/net-misc/freerdp/ChangeLog b/net-misc/freerdp/ChangeLog
index e3d9dffc3efb..c17602ac8399 100644
--- a/net-misc/freerdp/ChangeLog
+++ b/net-misc/freerdp/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/freerdp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/ChangeLog,v 1.50 2013/07/14 18:26:48 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/ChangeLog,v 1.51 2013/07/14 18:59:29 floppym Exp $
+
+*freerdp-1.1.0_beta1_p20130710 (14 Jul 2013)
+
+  14 Jul 2013; Mike Gilbert <floppym@gentoo.org>
+  +freerdp-1.1.0_beta1_p20130710.ebuild, freerdp-1.1.0_alpha20121004-r1.ebuild,
+  freerdp-9999.1.ebuild:
+  Add another snapshot.
 
 *freerdp-1.1.0_alpha20121004-r1 (14 Jul 2013)
 
diff --git a/net-misc/freerdp/freerdp-1.1.0_beta1_p20130710.ebuild b/net-misc/freerdp/freerdp-1.1.0_beta1_p20130710.ebuild
new file mode 100644
index 000000000000..c772a3ba5744
--- /dev/null
+++ b/net-misc/freerdp/freerdp-1.1.0_beta1_p20130710.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-1.1.0_beta1_p20130710.ebuild,v 1.1 2013/07/14 18:59:28 floppym Exp $
+
+EAPI="5"
+
+inherit cmake-utils vcs-snapshot
+
+if [[ ${PV} != 9999* ]]; then
+	COMMIT="780d451afad21a22d2af6bd030ee71311856f038"
+	SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+else
+	inherit git-2
+	SRC_URI=""
+	EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
+		https://github.com/FreeRDP/FreeRDP.git"
+	KEYWORDS=""
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="alsa +channels +client cups debug directfb doc ffmpeg gstreamer jpeg
+	pulseaudio server smartcard sse2 test X xinerama xv"
+
+RDEPEND="
+	dev-libs/openssl
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	client? (
+		directfb? ( dev-libs/DirectFB )
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			xinerama? ( x11-libs/libXinerama )
+			xv? ( x11-libs/libXv )
+		)
+	)
+	ffmpeg? ( virtual/ffmpeg )
+	gstreamer? (
+		media-libs/gstreamer:0.10
+		media-libs/gst-plugins-base:0.10
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}
+	client? ( X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) ) )
+"
+
+DOCS=( README )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with alsa ALSA)
+		$(cmake-utils_use_with channels CHANNELS)
+		$(cmake-utils_use_with client CLIENT)
+		$(cmake-utils_use_with cups CUPS)
+		$(cmake-utils_use_with debug DEBUG_ALL)
+		$(cmake-utils_use_with doc MANPAGES)
+		$(cmake-utils_use_with directfb DIRECTFB)
+		$(cmake-utils_use_with ffmpeg FFMPEG)
+		$(cmake-utils_use_with gstreamer GSTREAMER)
+		$(cmake-utils_use_with jpeg JPEG)
+		$(cmake-utils_use_with pulseaudio PULSEAUDIO)
+		$(cmake-utils_use_with server SERVER)
+		$(cmake-utils_use_with smartcard PCSC)
+		$(cmake-utils_use_with sse2 SSE2)
+		$(cmake-utils_use_with X X11)
+		$(cmake-utils_use_with xinerama XINERAMA)
+		$(cmake-utils_use_with xv XV)
+		$(cmake-utils_use_build test TESTING)
+	)
+	cmake-utils_src_configure
+}
diff --git a/net-misc/freerdp/freerdp-9999.1.ebuild b/net-misc/freerdp/freerdp-9999.1.ebuild
index b64d3af08e96..84a2fdc64b9b 100644
--- a/net-misc/freerdp/freerdp-9999.1.ebuild
+++ b/net-misc/freerdp/freerdp-9999.1.ebuild
@@ -1,13 +1,13 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-9999.1.ebuild,v 1.15 2013/06/10 00:39:08 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-9999.1.ebuild,v 1.16 2013/07/14 18:59:29 floppym Exp $
 
 EAPI="5"
 
 inherit cmake-utils vcs-snapshot
 
 if [[ ${PV} != 9999* ]]; then
-	COMMIT="04752f0144f76189bd8527243a939e13acedc8cc"
+	COMMIT="780d451afad21a22d2af6bd030ee71311856f038"
 	SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~x86"
 else