Version bump.

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

2 files changed, 75 insertions, 1 deletions

diff --git a/net-misc/csync/ChangeLog b/net-misc/csync/ChangeLog
index a0473c7ab146..253a309edb33 100644
--- a/net-misc/csync/ChangeLog
+++ b/net-misc/csync/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/csync
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/csync/ChangeLog,v 1.7 2012/10/17 06:30:20 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/csync/ChangeLog,v 1.8 2012/11/16 19:39:11 johu Exp $
+
+*csync-0.60.1 (16 Nov 2012)
+
+  16 Nov 2012; Johannes Huber <johu@gentoo.org> +csync-0.60.1.ebuild:
+  Version bump.
 
 *csync-0.60.0-r1 (17 Oct 2012)
 
diff --git a/net-misc/csync/csync-0.60.1.ebuild b/net-misc/csync/csync-0.60.1.ebuild
new file mode 100644
index 000000000000..4114888a1a53
--- /dev/null
+++ b/net-misc/csync/csync-0.60.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/csync/csync-0.60.1.ebuild,v 1.1 2012/11/16 19:39:11 johu Exp $
+
+EAPI=4
+
+inherit base cmake-utils
+
+DESCRIPTION="A file synchronizer especially designed for you, the normal user"
+HOMEPAGE="http://csync.org/"
+SRC_URI="http://download.owncloud.com/download/o${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc log samba +sftp test +webdav"
+
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/iniparser-3.1
+	dev-libs/openssl:0
+	log? ( dev-libs/log4c )
+	samba? ( net-fs/samba )
+	sftp? ( net-libs/libssh )
+	webdav? ( net-libs/neon )
+"
+DEPEND="${DEPEND}
+	app-text/asciidoc
+	doc? ( app-doc/doxygen )
+	test? ( dev-libs/check )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-automagicness.patch"
+)
+
+S="${WORKDIR}/o${P}"
+
+src_prepare() {
+	base_src_prepare
+
+	if ! use doc; then
+		sed -i \
+			-e 's:add_subdirectory(doc)::' \
+			CMakeLists.txt || die
+	fi
+
+	# punt owncloud test as it uses weird cmocka framework
+	sed -i \
+		-e 's:add_subdirectory(ownCloud)::' \
+		tests/CMakeLists.txt || die
+	# proper docdir
+	sed -i \
+		-e "s:/doc/ocsync:/doc/${PF}:" \
+		doc/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DLOG_TO_CALLBACK=ON"
+		$(cmake-utils_use test UNIT_TESTING)
+		$(cmake-utils_use_with doc APIDOC)
+		$(cmake-utils_use_with log Log4C)
+		$(cmake-utils_use_with samba Libsmbclient)
+		$(cmake-utils_use_with sftp LibSSH)
+		$(cmake-utils_use_with webdav Neon)
+	)
+	cmake-utils_src_configure
+}