Add a snapshot.

(Portage version: 2.2.0_alpha92/cvs/Linux x86_64)

3 files changed, 112 insertions, 9 deletions

diff --git a/net-misc/freerdp/ChangeLog b/net-misc/freerdp/ChangeLog
index 1f0e38632fbb..46fa380880f7 100644
--- a/net-misc/freerdp/ChangeLog
+++ b/net-misc/freerdp/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/freerdp
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/ChangeLog,v 1.26 2012/02/29 23:26:39 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/ChangeLog,v 1.27 2012/03/19 15:12:25 floppym Exp $
+
+*freerdp-1.0.1_p20120318 (19 Mar 2012)
+
+  19 Mar 2012; Mike Gilbert <floppym@gentoo.org>
+  +freerdp-1.0.1_p20120318.ebuild, freerdp-9999.1.ebuild:
+  Add a snapshot.
 
   29 Feb 2012; Mike Gilbert <floppym@gentoo.org> freerdp-1.0.0.ebuild,
   freerdp-1.0.1.ebuild:
diff --git a/net-misc/freerdp/freerdp-1.0.1_p20120318.ebuild b/net-misc/freerdp/freerdp-1.0.1_p20120318.ebuild
new file mode 100644
index 000000000000..2b542b3f5bae
--- /dev/null
+++ b/net-misc/freerdp/freerdp-1.0.1_p20120318.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-1.0.1_p20120318.ebuild,v 1.1 2012/03/19 15:12:25 floppym Exp $
+
+EAPI="4"
+
+inherit cmake-utils
+
+if [[ ${PV} != 9999* ]]; then
+	SRC_URI="https://github.com/downloads/FreeRDP/FreeRDP/${P}.tar.gz
+		mirror://gentoo/${P}.tar.gz
+		http://dev.gentoo.org/~floppym/distfiles/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+else
+	inherit git-2
+	SRC_URI=""
+	EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
+		https://github.com/FreeRDP/FreeRDP.git"
+	KEYWORDS=""
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="alsa cups directfb doc ffmpeg pulseaudio smartcard sse2 test X xinerama xv"
+
+FREERDP_DEBUG="transport chanman svc dvc kbd nla nego certificate license gdi
+	rfx x11 rail xv scard orders redir"
+IUSE+=" $(printf 'debug-%s ' ${FREERDP_DEBUG})"
+
+RDEPEND="
+	dev-libs/openssl
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	directfb? ( dev-libs/DirectFB )
+	ffmpeg? ( virtual/ffmpeg )
+	pulseaudio? ( media-sound/pulseaudio )
+	smartcard? ( sys-apps/pcsc-lite )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXcursor
+		x11-libs/libXext
+		x11-libs/libxkbfile
+		xinerama? ( x11-libs/libXinerama )
+		xv? ( x11-libs/libXv )
+	)
+"
+DEPEND="${RDEPEND}
+	doc? (
+		X? (
+			app-text/docbook-xml-dtd:4.1.2
+			app-text/xmlto
+		)
+	)
+	test? ( dev-util/cunit )
+"
+
+DOCS=( README )
+
+# Test suite segfaults
+RESTRICT="test"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with alsa ALSA)
+		$(cmake-utils_use_with cups CUPS)
+		$(cmake-utils_use_with doc MANPAGES)
+		$(cmake-utils_use_with directfb DIRECTFB)
+		$(cmake-utils_use_with ffmpeg FFMPEG)
+		$(cmake-utils_use_with pulseaudio PULSEAUDIO)
+		$(cmake-utils_use_with smartcard PCSC)
+		$(cmake-utils_use_with sse2 SSE2)
+		$(cmake-utils_use_with test CUNIT)
+		$(cmake-utils_use_with X X11)
+		$(cmake-utils_use_with X XCURSOR)
+		$(cmake-utils_use_with X XEXT)
+		$(cmake-utils_use_with X XKBFILE)
+		$(cmake-utils_use_with xinerama XINERAMA)
+		$(cmake-utils_use_with xv XV)
+	)
+	for i in ${FREERDP_DEBUG}; do
+		mycmakeargs+=(
+			$(cmake-utils_use_with debug-${i} DEBUG_$(LC_ALL=C echo ${i} | tr a-z A-Z))
+		)
+	done
+	cmake-utils_src_configure
+}
diff --git a/net-misc/freerdp/freerdp-9999.1.ebuild b/net-misc/freerdp/freerdp-9999.1.ebuild
index 1a29b3e2bc69..dc303de32b4a 100644
--- a/net-misc/freerdp/freerdp-9999.1.ebuild
+++ b/net-misc/freerdp/freerdp-9999.1.ebuild
@@ -1,20 +1,29 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-9999.1.ebuild,v 1.6 2012/01/16 20:51:51 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-9999.1.ebuild,v 1.7 2012/03/19 15:12:25 floppym Exp $
 
 EAPI="4"
 
-inherit cmake-utils git-2
+inherit cmake-utils
+
+if [[ ${PV} != 9999* ]]; then
+	SRC_URI="https://github.com/downloads/FreeRDP/FreeRDP/${P}.tar.gz
+		mirror://gentoo/${P}.tar.gz
+		http://dev.gentoo.org/~floppym/distfiles/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+else
+	inherit git-2
+	SRC_URI=""
+	EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
+		https://github.com/FreeRDP/FreeRDP.git"
+	KEYWORDS=""
+fi
 
 DESCRIPTION="Free implementation of the Remote Desktop Protocol"
 HOMEPAGE="http://www.freerdp.com/"
-SRC_URI=""
-EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
-	https://github.com/FreeRDP/FreeRDP.git"
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS=""
 IUSE="alsa cups directfb doc ffmpeg pulseaudio smartcard sse2 test X xinerama xv"
 
 FREERDP_DEBUG="transport chanman svc dvc kbd nla nego certificate license gdi
@@ -54,8 +63,6 @@ DOCS=( README )
 # Test suite segfaults
 RESTRICT="test"
 
-CMAKE_VERBOSE=1
-
 src_configure() {
 	local mycmakeargs=(
 		$(cmake-utils_use_with alsa ALSA)