Revision bump, so users can rebuild rtorrent with canvas colour patch.

(Portage version: 2.2_rc61/cvs/Linux x86_64)

2 files changed, 54 insertions, 1 deletions

diff --git a/net-p2p/rtorrent/ChangeLog b/net-p2p/rtorrent/ChangeLog
index ec4db6c0ffef..82c3942cf372 100644
--- a/net-p2p/rtorrent/ChangeLog
+++ b/net-p2p/rtorrent/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-p2p/rtorrent
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/rtorrent/ChangeLog,v 1.147 2010/01/21 11:19:34 cla Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/rtorrent/ChangeLog,v 1.148 2010/01/22 13:37:42 cla Exp $
+
+*rtorrent-0.8.6-r1 (22 Jan 2010)
+
+  22 Jan 2010; Dawid Węgliński <cla@gentoo.org> +rtorrent-0.8.6-r1.ebuild:
+  Revision bump, so users can rebuild rtorrent with canvas colour patch.
 
   21 Jan 2010; Dawid Węgliński <cla@gentoo.org> rtorrent-0.8.6.ebuild,
   +files/rtorrent-0.8.6-canvas-fix.patch:
diff --git a/net-p2p/rtorrent/rtorrent-0.8.6-r1.ebuild b/net-p2p/rtorrent/rtorrent-0.8.6-r1.ebuild
new file mode 100644
index 000000000000..8c74d3f743b2
--- /dev/null
+++ b/net-p2p/rtorrent/rtorrent-0.8.6-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/rtorrent/rtorrent-0.8.6-r1.ebuild,v 1.1 2010/01/22 13:37:42 cla Exp $
+
+EAPI=2
+
+inherit eutils
+
+DESCRIPTION="BitTorrent Client using libtorrent"
+HOMEPAGE="http://libtorrent.rakshasa.no/"
+SRC_URI="http://libtorrent.rakshasa.no/downloads/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="daemon debug ipv6 xmlrpc"
+
+COMMON_DEPEND=">=net-libs/libtorrent-0.12.${PV##*.}
+	>=dev-libs/libsigc++-2.2.2:2
+	>=net-misc/curl-7.19.1
+	sys-libs/ncurses
+	xmlrpc? ( dev-libs/xmlrpc-c )"
+RDEPEND="${COMMON_DEPEND}
+	daemon? ( app-misc/screen )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-canvas-fix.patch
+}
+
+src_configure() {
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable debug) \
+		$(use_enable ipv6) \
+		$(use_with xmlrpc xmlrpc-c)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS README TODO doc/rtorrent.rc
+
+	if use daemon; then
+		newinitd "${FILESDIR}/rtorrentd.init" rtorrentd || die "newinitd failed"
+		newconfd "${FILESDIR}/rtorrentd.conf" rtorrentd || die "newconfd failed"
+	fi
+}