Respect CXXFLAGS (bug #451186, bug #451188, AR (bug #451184).

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key A792A613)

2 files changed, 77 insertions, 1 deletions

diff --git a/net-proxy/havp/ChangeLog b/net-proxy/havp/ChangeLog
index 1aeb225ad577..4ffc1d073354 100644
--- a/net-proxy/havp/ChangeLog
+++ b/net-proxy/havp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-proxy/havp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/havp/ChangeLog,v 1.40 2013/01/10 17:09:42 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/havp/ChangeLog,v 1.41 2013/01/10 17:26:47 jer Exp $
+
+*havp-0.92a-r1 (10 Jan 2013)
+
+  10 Jan 2013; Jeroen Roovers <jer@gentoo.org> +havp-0.92a-r1.ebuild:
+  Respect CXXFLAGS (bug #451186, bug #451188, AR (bug #451184).
 
   10 Jan 2013; Jeroen Roovers <jer@gentoo.org> -havp-0.90-r1.ebuild,
   -files/havp-0.90-gcc44.patch:
diff --git a/net-proxy/havp/havp-0.92a-r1.ebuild b/net-proxy/havp/havp-0.92a-r1.ebuild
new file mode 100644
index 000000000000..6dac7fa0aeb6
--- /dev/null
+++ b/net-proxy/havp/havp-0.92a-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/havp/havp-0.92a-r1.ebuild,v 1.1 2013/01/10 17:26:47 jer Exp $
+
+EAPI=4
+inherit autotools eutils toolchain-funcs user
+
+DESCRIPTION="HTTP AntiVirus Proxy"
+HOMEPAGE="http://www.server-side.de/"
+SRC_URI="http://www.server-side.de/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="clamav ssl"
+
+DEPEND="clamav? ( app-antivirus/clamav )"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /etc/${PN} ${PN}
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.92a-run.patch
+	sed -i configure.in -e '/^CFLAGS=/d' || die
+	eautoreconf
+}
+
+src_configure() {
+	tc-export AR
+	export CFLAGS="${CXXFLAGS}"
+	econf \
+		$(use_enable clamav) \
+		$(use_enable ssl ssl-tunnel) \
+		--localstatedir=/var
+}
+
+src_install() {
+	exeinto /usr/sbin
+	doexe ${PN}/${PN}
+
+	newinitd "${FILESDIR}/${PN}.initd" ${PN}
+
+	insinto /etc
+	rm -r etc/${PN}/${PN}.config.in
+	doins -r etc/${PN}
+
+	dodoc ChangeLog
+}
+
+pkg_postinst() {
+	ewarn "/var/tmp/${PN} must be on a filesystem with mandatory locks!"
+	ewarn "You should add  \"mand\" to the mount options on the relevant line in /etc/fstab."
+
+	if use ssl; then
+		echo
+		ewarn "Note: ssl USE flag only enable SSL pass-through, which means that"
+		ewarn "      HTTPS pages will not be scanned for viruses!"
+		ewarn "      It is impossible to decrypt data sent through SSL connections without knowing"
+		ewarn "      the private key of the used certificate."
+	fi
+
+	if use clamav; then
+		echo
+		ewarn "If you plan to use clamav daemon, you should make sure clamav user can read"
+		ewarn "/var/tmp/${PN} content. This can be accomplished by enabling AllowSupplementaryGroups"
+		ewarn "in /etc/clamd.conf and adding clamav user to the ${PN} group."
+	fi
+}