sci-chemistry/aria: Version Bump

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

1 files changed, 86 insertions, 0 deletions

diff --git a/sci-chemistry/aria/aria-2.3.2-r5.ebuild b/sci-chemistry/aria/aria-2.3.2-r5.ebuild
new file mode 100644
index 000000000000..19329f397269
--- /dev/null
+++ b/sci-chemistry/aria/aria-2.3.2-r5.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/aria/aria-2.3.2-r5.ebuild,v 1.1 2013/05/14 12:15:38 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+PYTHON_REQ_USE="tk"
+
+inherit base eutils python-single-r1 versionator
+
+MY_P="${PN}$(get_version_component_range 1-2 ${PV})"
+DATE="03.25.2013"
+
+DESCRIPTION="Automated NOE assignment and NMR structure calculation"
+HOMEPAGE="http://aria.pasteur.fr/"
+SRC_URI="http://aria.pasteur.fr/archives/${MY_P}.2_${DATE}.tar.gz"
+
+SLOT="0"
+LICENSE="cns"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+RDEPEND="
+	dev-tcltk/tix
+	dev-lang/tk
+	dev-python/numpy
+	dev-python/matplotlib[tk]
+	>=sci-chemistry/cns-1.2.1-r7[aria,openmp]
+	>=sci-chemistry/ccpn-2.2
+	sci-chemistry/clashlist
+	sci-chemistry/procheck
+	sci-libs/clashscore-db"
+DEPEND="${RDEPEND}"
+
+RESTRICT="fetch"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_nofetch(){
+	einfo "Go to http://aria.pasteur.fr/archives/aria2.3.2.tar.gz/view, download ${A}"
+	einfo "and place it in ${DISTDIR}"
+}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_test(){
+	export CCPNMR_TOP_DIR=$(python_get_sitedir)
+	export PYTHONPATH=.:${CCPNMR_TOP_DIR}/ccpn/python
+	${PYTHON} check.py || die
+}
+
+src_install(){
+	python_moduleinto ${PN}
+	python_domodule src aria2.py
+	python_moduleinto ${PN}/cns
+	python_domodule cns/{protocols,toppar,src/helplib}
+
+	if use examples; then
+		insinto /usr/share/${P}/
+		doins -r examples
+	fi
+
+	# ENV
+	cat >> "${T}"/20aria <<- EOF
+	ARIA2="$(python_get_sitedir)/${PN}"
+	EOF
+
+	doenvd "${T}"/20aria
+
+	# Launch Wrapper
+	cat >> "${T}"/aria <<- EOF
+	#!/bin/sh
+	export CCPNMR_TOP_DIR="$(python_get_sitedir)"
+	export PYTHONPATH="$(python_get_sitedir)/ccpn/python"
+	exec "${PYTHON}" -O "\${ARIA2}"/aria2.py \$@
+	EOF
+
+	dobin "${T}"/aria
+	dosym aria /usr/bin/aria2
+
+	dodoc README
+	python_optimize "${D}/$(python_get_sitedir)"
+}