sci-chemistry/relax: Version Bump

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

1 files changed, 63 insertions, 0 deletions

diff --git a/sci-chemistry/relax/relax-2.2.5.ebuild b/sci-chemistry/relax/relax-2.2.5.ebuild
new file mode 100644
index 000000000000..64b61dd5451b
--- /dev/null
+++ b/sci-chemistry/relax/relax-2.2.5.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/relax/relax-2.2.5.ebuild,v 1.1 2013/05/13 08:42:18 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+
+WX_GTK_VER="2.8"
+
+inherit eutils python-single-r1 scons-utils toolchain-funcs wxwidgets
+
+DESCRIPTION="Molecular dynamics by NMR data analysis"
+HOMEPAGE="http://www.nmr-relax.com/"
+SRC_URI="http://download.gna.org/relax/${P}.src.tar.bz2"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-chemistry/molmol
+	sci-chemistry/pymol
+	>=sci-libs/bmrblib-1.0.1_pre198[${PYTHON_USEDEP}]
+	>=sci-libs/minfx-1.0.4_pre98[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	sci-visualization/grace
+	sci-visualization/opendx
+	x11-libs/wxGTK:2.8[X]"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	wxwidgets_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	rm -rf minfx bmrblib || die
+	epatch "${FILESDIR}"/${PN}-2.2.1-gentoo.patch
+	tc-export CC
+}
+
+src_compile() {
+	escons
+}
+
+src_test() {
+	${EPYTHON} ./${PN}.py -s || die
+	${EPYTHON} ./${PN}.py -x || die
+}
+
+src_install() {
+	dodoc README docs/{CHANGES,COMMITTERS,JOBS,relax.pdf,prompt_screenshot.txt}
+
+	python_moduleinto ${PN}
+	python_domodule *
+
+	rm ${PN} README || die
+
+	make_wrapper ${PN}-nmr "${EPYTHON} $(python_get_sitedir)/${PN}/${PN}.py $@"
+}