Version bump, with new upstream numbering (see bug #184701). You will have to mask older versions to use it until we can stabilize this version and remove the others.

(Portage version: 2.1.3_rc8)

1 files changed, 85 insertions, 0 deletions

diff --git a/sci-electronics/geda/geda-1.1.1.ebuild b/sci-electronics/geda/geda-1.1.1.ebuild
new file mode 100644
index 000000000000..8d8b9d9377c8
--- /dev/null
+++ b/sci-electronics/geda/geda-1.1.1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/geda/geda-1.1.1.ebuild,v 1.1 2007/07/19 09:35:13 calchan Exp $
+
+inherit eutils
+
+SUBDIR="v1.1"
+S="${WORKDIR}"
+
+HOMEPAGE="http://www.geda.seul.org"
+DESCRIPTION="geda is a core metapackage which compiles all the necessary components you would need for a minimal gEDA/gaf system"
+SRC_URI="http://www.geda.seul.org/devel/${SUBDIR}/${PV}/geda-gattrib-${PV}.tar.gz
+	http://www.geda.seul.org/devel/${SUBDIR}/${PV}/geda-gnetlist-${PV}.tar.gz
+	http://www.geda.seul.org/devel/${SUBDIR}/${PV}/geda-gschem-${PV}.tar.gz
+	http://www.geda.seul.org/devel/${SUBDIR}/${PV}/geda-gsymcheck-${PV}.tar.gz
+	http://www.geda.seul.org/devel/${SUBDIR}/${PV}/geda-symbols-${PV}.tar.gz
+	http://www.geda.seul.org/devel/${SUBDIR}/${PV}/geda-utils-${PV}.tar.gz
+	doc? ( http://www.geda.seul.org/devel/${SUBDIR}/${PV}/geda-docs-${PV}.tar.gz )
+	examples? ( http://www.geda.seul.org/devel/${SUBDIR}/${PV}/geda-examples-${PV}.tar.gz )"
+
+IUSE="doc examples gd"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+SLOT="0"
+
+DEPEND=">=x11-libs/gtk+-2.4
+	>=dev-scheme/guile-1.6.3
+	=sci-libs/libgeda-${PV}"
+
+pkg_setup() {
+	if has_version ">=dev-scheme/guile-1.8" ; then
+		built_with_use "dev-scheme/guile" deprecated \
+			|| die "You need either <dev-scheme/guile-1.8, or >=dev-scheme/guile-1.8 with USE=deprecated"
+	fi
+	if use gd ; then
+		built_with_use sci-libs/libgeda gd || die "sci-libs/libgeda must be compiled with USE=gd"
+	else
+		! built_with_use sci-libs/libgeda gd || die "sci-libs/libgeda must be compiled with USE=-gd"
+	fi
+}
+
+src_compile() {
+	for subdir in geda-{gattrib,gnetlist,gschem,gsymcheck,symbols,utils}-${PV}; do
+		cd ${S}/${subdir}
+		econf \
+			--disable-dependency-tracking \
+			--with-docdir=/usr/share/doc/${PF} \
+			--with-pcbconfdir=/usr/share/pcb \
+			--with-pcbm4dir=/usr/share/pcb/m4 \
+			|| die "Configuration failed in ${subdir}"
+		emake || die "Compilation failed in ${subdir}"
+	done
+
+	if use doc ; then
+		cd ${S}/geda-docs-${PV}
+		econf --with-docdir=/usr/share/doc/${PF} || die "Configuration failed in geda-docs-${PV}"
+		emake || die "Compilation failed in geda-docs-${PV}"
+	fi
+}
+
+src_install () {
+	for subdir in {gattrib,gnetlist,gschem,gsymcheck,symbols,utils}; do
+		cd ${S}/geda-${subdir}-${PV}
+		emake DESTDIR=${D} install || die "Installation failed in geda-${subdir}-${PV}"
+		newdoc AUTHORS AUTHORS.${subdir}
+		newdoc BUGS BUGS.${subdir}
+		for READMEx in $(ls README*); do
+			newdoc ${READMEx} ${READMEx}.${subdir}
+		done
+	done
+
+	rm ${D}/usr/share/gEDA/sym/gnetman -Rf # Fix collision with gnetman; bug #77361.
+
+	if use doc ; then
+		cd ${S}/geda-docs-${PV}
+		emake DESTDIR=${D} install || die "Installation failed in geda-docs-${PV}"
+	fi
+
+	if use examples ; then
+		cd ${S}
+		mv geda-examples-${PV} examples
+		insinto /usr/share/gEDA
+		doins -r examples
+	fi
+}