sci-libs/mathgl: Version BUmp; Bump to python r1 eclasses; fix numpy header path issues, #469420

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

4 files changed, 171 insertions, 17 deletions

diff --git a/sci-libs/mathgl/ChangeLog b/sci-libs/mathgl/ChangeLog
index c5fa59f2160b..b4f23f74ca26 100644
--- a/sci-libs/mathgl/ChangeLog
+++ b/sci-libs/mathgl/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sci-libs/mathgl
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/mathgl/ChangeLog,v 1.37 2013/06/07 22:53:05 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/mathgl/ChangeLog,v 1.38 2013/10/15 15:00:27 jlec Exp $
+
+*mathgl-2.1.3 (15 Oct 2013)
+
+  15 Oct 2013; Justin Lecher <jlec@gentoo.org> mathgl-2.1.2.ebuild,
+  +mathgl-2.1.3.ebuild, metadata.xml:
+  Version BUmp; Bump to python r1 eclasses; fix numpy header path issues,
+  #469420
 
   07 Jun 2013; Sébastien Fabbro <bicatali@gentoo.org> -mathgl-1.11.2.ebuild:
   Removed old
diff --git a/sci-libs/mathgl/mathgl-2.1.2.ebuild b/sci-libs/mathgl/mathgl-2.1.2.ebuild
index 4ffccd68b545..f22f34d949eb 100644
--- a/sci-libs/mathgl/mathgl-2.1.2.ebuild
+++ b/sci-libs/mathgl/mathgl-2.1.2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/mathgl/mathgl-2.1.2.ebuild,v 1.1 2013/03/21 15:40:47 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/mathgl/mathgl-2.1.2.ebuild,v 1.2 2013/10/15 15:00:27 jlec Exp $
 
 EAPI=5
 
@@ -57,7 +57,7 @@ pkg_setup() {
 src_unpack() {
 	unpack ${A}
 	[[ -d "${S}"/fonts ]] || mkdir "${S}"/fonts
-	cd "${S}"/fonts
+	cd "${S}"/fonts || die
 	unpack STIX_font.tgz
 }
 
@@ -71,11 +71,13 @@ src_prepare() {
 	echo "" > lang/install.m || die
 	# fix desktop file
 	sed -i -e 's/.png//' udav/udav.desktop || die
+	use python && append-cppflags -I"$($(PYTHON) -c 'import numpy; print(numpy.get_include())')"
 }
 
 src_configure() {
 	local mycmakeargs=(
 		-DHDF4_INCLUDE_DIR="${EPREFIX}/usr/include"
+		-DMGL_LIB_INSTALL_DIR="$(get_libdir)"
 		$(cmake-utils_use doc enable-doc)
 		$(cmake-utils_use fltk enable-fltk)
 		$(cmake-utils_use gif enable-gif)
@@ -101,9 +103,6 @@ src_configure() {
 		sed -i \
 			-e "s:--prefix=\(.*\) :--prefix=\$ENV{DESTDIR}\1 :" \
 			"${CMAKE_BUILD_DIR}"/lang/cmake_install.cmake || die
-		# fix location of numpy
-		use python && append-cppflags \
-			-I$(echo "import numpy; print(numpy.get_include())" | "$(PYTHON)" - 2>/dev/null)
 	fi
 
 }
diff --git a/sci-libs/mathgl/mathgl-2.1.3.ebuild b/sci-libs/mathgl/mathgl-2.1.3.ebuild
new file mode 100644
index 000000000000..8c5e6c89f5af
--- /dev/null
+++ b/sci-libs/mathgl/mathgl-2.1.3.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/mathgl/mathgl-2.1.3.ebuild,v 1.1 2013/10/15 15:00:27 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+WX_GTK_VER=2.8
+
+inherit cmake-utils eutils python-single-r1 wxwidgets multilib flag-o-matic
+
+DESCRIPTION="Math Graphics Library"
+HOMEPAGE="http://mathgl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz mirror://sourceforge/${PN}/STIX_font.tgz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc fltk gif glut gsl hdf hdf5 jpeg mpi octave opengl pdf
+	png python qt4 static-libs threads wxwidgets zlib"
+
+LANGS="ru"
+for l in ${LANGS}; do
+	IUSE+=" linguas_${l}"
+done
+
+RDEPEND="
+	!sci-visualization/udav
+	virtual/opengl
+	fltk? ( x11-libs/fltk:1 )
+	gif? ( media-libs/giflib )
+	glut? ( media-libs/freeglut )
+	gsl? ( sci-libs/gsl )
+	hdf? ( sci-libs/hdf )
+	hdf5? ( >=sci-libs/hdf5-1.8[mpi=] )
+	jpeg? ( virtual/jpeg )
+	octave? ( >=sci-mathematics/octave-3.4.0 )
+	pdf? ( media-libs/libharu )
+	png? ( media-libs/libpng )
+	python? ( dev-python/numpy[${PYTHON_USEDEP}] ${PYTHON_DEPS} )
+	qt4? ( dev-qt/qtgui:4 )
+	wxwidgets? ( x11-libs/wxGTK:2.8 )
+	zlib? ( sys-libs/zlib )"
+
+DEPEND="${RDEPEND}
+	doc? ( app-text/texi2html virtual/texi2dvi )
+	octave? ( dev-lang/swig )
+	python? ( dev-lang/swig )"
+
+REQUIRED_USE="
+	mpi? ( hdf5 )
+	png? ( zlib )
+	pdf? ( png )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use mpi && export CC=mpicc CXX=mpicxx
+	use python && python-single-r1_pkg_setup
+	use wxwidgets && wxwidgets_pkg_setup
+}
+
+src_unpack() {
+	unpack ${A}
+	[[ -d "${S}"/fonts ]] || mkdir "${S}"/fonts
+	cd "${S}"/fonts || die
+	unpack STIX_font.tgz
+}
+
+src_prepare() {
+	# fix for location of hdf headers
+	sed -i -e 's:hdf/::g' src/data_io.cpp || die
+	# bored of reporting bad libdir upstream
+	sed -i \
+		-e '/DESTINATION/s:lib$:lib${LIB_SUFFIX}:g' \
+		{src,widgets}/CMakeLists.txt || die
+	echo "" > lang/install.m || die
+	# fix desktop file
+	sed -i -e 's/.png//' udav/udav.desktop || die
+	use python && append-cppflags -I"$(${EPYTHON} -c 'import numpy; print(numpy.get_include())')"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# No clue about this option:
+		# option(enable-mgl2 "Use names 'libmgl2-*' instead of 'libmgl-*'")
+		-DHDF4_INCLUDE_DIR="${EPREFIX}/usr/include"
+		-DMGL_LIB_INSTALL_DIR="$(get_libdir)"
+		$(cmake-utils_use doc enable-doc)
+		$(cmake-utils_use fltk enable-fltk)
+		$(cmake-utils_use gif enable-gif)
+		$(cmake-utils_use glut enable-glut)
+		$(cmake-utils_use gsl enable-gsl)
+		$(cmake-utils_use hdf enable-hdf4)
+		$(cmake-utils_use hdf5 enable-hdf5_18)
+		$(cmake-utils_use jpeg enable-jpeg)
+		$(cmake-utils_use mpi enable-mpi)
+		$(cmake-utils_use octave enable-octave)
+		$(cmake-utils_use opengl enable-opengl)
+		$(cmake-utils_use pdf enable-pdf)
+		$(cmake-utils_use png enable-png)
+		$(cmake-utils_use qt4 enable-qt)
+		$(cmake-utils_use threads enable-pthread)
+		$(cmake-utils_use python enable-python)
+		$(cmake-utils_use wxwidgets enable-wx)
+		$(cmake-utils_use zlib enable-zlib)
+	)
+	cmake-utils_src_configure
+	# to whoever cares: TODO: do for multiple python ABI
+	if use python; then
+		sed -i \
+			-e "s:--prefix=\(.*\) :--prefix=\$ENV{DESTDIR}\1 :" \
+			"${CMAKE_BUILD_DIR}"/lang/cmake_install.cmake || die
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc README* *.txt AUTHORS
+	use static-libs || rm "${ED}"/usr/$(get_libdir)/*.a
+	if use qt4 ; then
+		local lang
+		insinto /usr/share/udav
+		for lang in ${LANGS} ; do
+			use linguas_${lang} && doins udav/udav_${lang}.qm
+		done
+	fi
+	if use octave ; then
+		insinto /usr/share/${PN}/octave
+		doins "${CMAKE_BUILD_DIR}"/lang/${PN}.tar.gz
+	fi
+	use python && python_optimize
+}
+
+pkg_postinst() {
+	if use octave; then
+		octave <<-EOF
+		pkg install ${EROOT}/usr/share/${PN}/octave/${PN}.tar.gz
+		EOF
+	fi
+}
+
+pkg_prerm() {
+	if use octave; then
+		octave <<-EOF
+		pkg uninstall ${PN}
+		EOF
+	fi
+}
diff --git a/sci-libs/mathgl/metadata.xml b/sci-libs/mathgl/metadata.xml
index 433b634786fe..50c88744b103 100644
--- a/sci-libs/mathgl/metadata.xml
+++ b/sci-libs/mathgl/metadata.xml
@@ -1,20 +1,20 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>sci</herd>
-<maintainer>
-  <email>grozin@gentoo.org</email>
-  <name>Andrey Grozin</name>
-</maintainer>
-<longdescription>
+  <herd>sci</herd>
+  <maintainer>
+    <email>grozin@gentoo.org</email>
+    <name>Andrey Grozin</name>
+  </maintainer>
+  <longdescription>
   MathGL is a library for:
   * making high-quality scientific graphics
   * the fast data plotting and data processing of large data arrays
   * working in window and console modes and for easy embedding into other programs
 </longdescription>
-<use>
-  <flag name="hdf">Add support for the Hierarchical Data Format v.4 <pkg>sci-libs/hdf</pkg></flag>  
-  <flag name="octave">Add bindings for <pkg>sci-mathematics/octave</pkg></flag>
-  <flag name="double-precision">Add double precision calculations</flag>
-</use>
+  <use>
+    <flag name="hdf">Add support for the Hierarchical Data Format v.4 <pkg>sci-libs/hdf</pkg></flag>
+    <flag name="octave">Add bindings for <pkg>sci-mathematics/octave</pkg></flag>
+    <flag name="double-precision">Add double precision calculations</flag>
+  </use>
 </pkgmetadata>