Use --with-rootlibdir= instead of gen_usr_ldscript wrt #443710 by William Hubbs

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

3 files changed, 99 insertions, 5 deletions

diff --git a/sys-apps/kmod/ChangeLog b/sys-apps/kmod/ChangeLog
index 0cd7de440008..8e88aae7f754 100644
--- a/sys-apps/kmod/ChangeLog
+++ b/sys-apps/kmod/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/kmod
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.59 2012/11/25 08:29:47 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/ChangeLog,v 1.60 2012/11/25 09:42:58 ssuominen Exp $
+
+*kmod-11-r3 (25 Nov 2012)
+
+  25 Nov 2012; Samuli Suominen <ssuominen@gentoo.org> +kmod-11-r3.ebuild,
+  kmod-9999.ebuild:
+  Use --with-rootlibdir= instead of gen_usr_ldscript wrt #443710 by William
+  Hubbs
 
   24 Nov 2012; Samuli Suominen <ssuominen@gentoo.org>
   -files/kmod-8-gc-sections.patch, -kmod-10-r2.ebuild:
diff --git a/sys-apps/kmod/kmod-11-r3.ebuild b/sys-apps/kmod/kmod-11-r3.ebuild
new file mode 100644
index 000000000000..4d92fa5c56b1
--- /dev/null
+++ b/sys-apps/kmod/kmod-11-r3.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-11-r3.ebuild,v 1.1 2012/11/25 09:42:58 ssuominen Exp $
+
+EAPI=4
+
+inherit autotools eutils libtool multilib
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
+	inherit git-2
+else
+	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="library and tools for managing linux kernel modules"
+HOMEPAGE="http://git.kernel.org/?p=utils/kernel/kmod/kmod.git"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="debug doc lzma static-libs +tools zlib"
+
+# Upstream does not support running the test suite with custom configure flags.
+# I was also told that the test suite is intended for kmod developers.
+# So we have to restrict it.
+# See bug #408915.
+RESTRICT="test"
+
+RDEPEND="!sys-apps/module-init-tools
+	!sys-apps/modutils
+	lzma? ( >=app-arch/xz-utils-5.0.4-r1 )
+	zlib? ( >=sys-libs/zlib-1.2.6 )" #427130
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	doc? ( dev-util/gtk-doc )
+	lzma? ( virtual/pkgconfig )
+	zlib? ( virtual/pkgconfig )"
+
+src_prepare()
+{
+	if [ ! -e configure ]; then
+		if use doc; then
+			gtkdocize --copy --docdir libkmod/docs || die
+		else
+			touch libkmod/docs/gtk-doc.make
+		fi
+		eautoreconf
+	else
+		elibtoolize
+	fi
+}
+
+src_configure()
+{
+	econf \
+		--bindir=/sbin \
+		$(use_enable static-libs static) \
+		$(use_enable tools) \
+		$(use_enable debug) \
+		$(use_enable doc gtk-doc) \
+		$(use_with lzma xz) \
+		$(use_with zlib) \
+		--with-rootlibdir=/$(get_libdir)
+}
+
+src_install()
+{
+	default
+	prune_libtool_files
+
+	if use tools; then
+		local cmd
+		for cmd in depmod insmod modinfo modprobe rmmod; do
+			dosym kmod /sbin/${cmd}
+		done
+		dosym /sbin/kmod /bin/lsmod
+	fi
+
+	cat <<-EOF > "${T}"/usb-load-ehci-first.conf
+	softdep uhci_hcd pre: ehci_hcd
+	softdep ohci_hcd pre: ehci_hcd
+	EOF
+
+	insinto /lib/modprobe.d
+	doins "${T}"/usb-load-ehci-first.conf #260139
+}
diff --git a/sys-apps/kmod/kmod-9999.ebuild b/sys-apps/kmod/kmod-9999.ebuild
index 66068e1fbe06..fc5764446f72 100644
--- a/sys-apps/kmod/kmod-9999.ebuild
+++ b/sys-apps/kmod/kmod-9999.ebuild
@@ -1,10 +1,10 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.39 2012/11/24 20:47:20 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/kmod/kmod-9999.ebuild,v 1.40 2012/11/25 09:42:58 ssuominen Exp $
 
 EAPI=4
 
-inherit autotools eutils libtool toolchain-funcs
+inherit autotools eutils libtool multilib
 
 if [[ ${PV} == 9999 ]]; then
 	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
@@ -60,14 +60,14 @@ src_configure()
 		$(use_enable debug) \
 		$(use_enable doc gtk-doc) \
 		$(use_with lzma xz) \
-		$(use_with zlib)
+		$(use_with zlib) \
+		--with-rootlibdir=/$(get_libdir)
 }
 
 src_install()
 {
 	default
 	prune_libtool_files
-	gen_usr_ldscript -a kmod
 
 	if use tools; then
 		local cmd