Merge live/snapshot ebuilds, and touch it up a bit.

(Portage version: 2.2.0_alpha79/cvs/Linux x86_64)

5 files changed, 139 insertions, 48 deletions

diff --git a/sys-apps/superiotool/ChangeLog b/sys-apps/superiotool/ChangeLog
index 641d978aadd3..a95f7b994040 100644
--- a/sys-apps/superiotool/ChangeLog
+++ b/sys-apps/superiotool/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for sys-apps/superiotool
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/superiotool/ChangeLog,v 1.3 2011/01/09 22:19:08 idl0r Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/superiotool/ChangeLog,v 1.4 2011/12/05 17:53:39 vapier Exp $
+
+*superiotool-99999999 (05 Dec 2011)
+*superiotool-6637 (05 Dec 2011)
+
+  05 Dec 2011; Mike Frysinger <vapier@gentoo.org> +superiotool-6637.ebuild,
+  -superiotool-9999.ebuild, +superiotool-99999999.ebuild,
+  +files/make-tarball.sh:
+  Merge live/snapshot ebuilds, and touch it up a bit.
 
   09 Jan 2011; Christian Ruppert <idl0r@gentoo.org> superiotool-9999.ebuild:
   Define SUPERIOTOOL_VERSION through ESVN_WC_REVISION.
diff --git a/sys-apps/superiotool/files/make-tarball.sh b/sys-apps/superiotool/files/make-tarball.sh
new file mode 100755
index 000000000000..3711db140db3
--- /dev/null
+++ b/sys-apps/superiotool/files/make-tarball.sh
@@ -0,0 +1,34 @@
+#!/bin/bash
+
+. /etc/init.d/functions.sh
+
+svnrev() { svn info "$1" | awk '$1 == "Revision:" { print $NF }'; }
+
+PN=superiotool
+SVN_ROOT=${2:-/usr/local/src}
+srcdir=${SVN_ROOT}/${PN}
+PV=${1:-$(svnrev "${srcdir}")}
+
+P=${PN}-${PV}
+T=/tmp
+
+if [[ -d ${srcdir} ]] ; then
+	cd "${T}" || die
+
+	rm -rf ${P}
+
+	ebegin "Exporting ${srcdir} ${PV} to ${P}"
+	svn export -q -r ${PV} ${srcdir} ${P}
+	eend $? || die
+
+	ebegin "Creating ${P}.tar.xz"
+	tar cf - ${P} | xz > ${P}.tar.xz
+	eend $?
+
+	einfo "Tarball now ready at: ${T}/${P}.tar.xz"
+else
+	einfo "You need to run:"
+	einfo " cd ${base}"
+	einfo " svn co svn://coreboot.org/coreboot/trunk/util/superiotool"
+	die "need svn checkout dir"
+fi
diff --git a/sys-apps/superiotool/superiotool-6637.ebuild b/sys-apps/superiotool/superiotool-6637.ebuild
new file mode 100644
index 000000000000..a5597192f2e8
--- /dev/null
+++ b/sys-apps/superiotool/superiotool-6637.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/superiotool/superiotool-6637.ebuild,v 1.1 2011/12/05 17:53:39 vapier Exp $
+
+EAPI="4"
+
+inherit toolchain-funcs eutils
+
+if [[ ${PV} == "99999999" ]] ; then
+	ESVN_REPO_URI="svn://coreboot.org/coreboot/trunk/util/${PN}"
+	inherit subversion
+	SRC_URI=""
+else
+	SRC_URI="mirror://gentoo/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="util to detect Super I/O chips and functionality"
+HOMEPAGE="http://www.coreboot.org/Superiotool"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="pci"
+
+RDEPEND="pci? ( sys-apps/pciutils )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+src_prepare() {
+	sed -i \
+		-e 's:-Werror ::' \
+		-e 's:-O2 ::' \
+		-e 's:\s\+\?-lz\s\+\?::' \
+		-e "/^CONFIG_PCI =/s:=.*:=$(usex pci yes no):" \
+		-e '/PREFIX/s:=.*:= /usr:' \
+		Makefile || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		SVNDEF="-D'SUPERIOTOOL_VERSION=\"${ESVN_WC_REVISION}\"'"
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+	dodoc README
+}
diff --git a/sys-apps/superiotool/superiotool-9999.ebuild b/sys-apps/superiotool/superiotool-9999.ebuild
deleted file mode 100644
index 44f47af753c0..000000000000
--- a/sys-apps/superiotool/superiotool-9999.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/superiotool/superiotool-9999.ebuild,v 1.3 2011/01/09 22:19:08 idl0r Exp $
-
-EAPI=3
-
-inherit toolchain-funcs subversion
-
-DESCRIPTION="user-space utility to detect Super I/O chips and functionality to
-get more information about it"
-HOMEPAGE="http://coreboot.org"
-SRC_URI=""
-ESVN_REPO_URI="svn://coreboot.org/coreboot/trunk/util/${PN}"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS=""
-IUSE="pci"
-
-DEPEND="pci? ( sys-apps/pciutils )"
-RDEPEND="${DEPEND}"
-
-src_prepare() {
-	sed -i -e 's:-Werror ::' \
-		-e 's:-O2 ::' \
-		-e 's:\s\+\?-lz\s\+\?::' \
-		Makefile || die
-}
-
-src_compile() {
-	local config_pci
-
-	if use pci; then
-		config_pci="yes"
-	else
-		config_pci="no"
-	fi
-
-	emake CC=$(tc-getCC) CONFIG_PCI=${config_pci} \
-		SVNDEF="-D'SUPERIOTOOL_VERSION=\"${ESVN_WC_REVISION}\"'" || die
-}
-
-src_install() {
-	dosbin superiotool || die
-	doman superiotool.8
-	dodoc README
-}
diff --git a/sys-apps/superiotool/superiotool-99999999.ebuild b/sys-apps/superiotool/superiotool-99999999.ebuild
new file mode 100644
index 000000000000..0fcf8caa6130
--- /dev/null
+++ b/sys-apps/superiotool/superiotool-99999999.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/superiotool/superiotool-99999999.ebuild,v 1.1 2011/12/05 17:53:39 vapier Exp $
+
+EAPI="4"
+
+inherit toolchain-funcs eutils
+
+if [[ ${PV} == "99999999" ]] ; then
+	ESVN_REPO_URI="svn://coreboot.org/coreboot/trunk/util/${PN}"
+	inherit subversion
+	SRC_URI=""
+else
+	SRC_URI="mirror://gentoo/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="util to detect Super I/O chips and functionality"
+HOMEPAGE="http://www.coreboot.org/Superiotool"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="pci"
+
+RDEPEND="pci? ( sys-apps/pciutils )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils"
+
+src_prepare() {
+	sed -i \
+		-e 's:-Werror ::' \
+		-e 's:-O2 ::' \
+		-e 's:\s\+\?-lz\s\+\?::' \
+		-e "/^CONFIG_PCI =/s:=.*:=$(usex pci yes no):" \
+		-e '/PREFIX/s:=.*:= /usr:' \
+		Makefile || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		SVNDEF="-D'SUPERIOTOOL_VERSION=\"${ESVN_WC_REVISION}\"'"
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+	dodoc README
+}