Update to EAPI=2, add editor-wrapper support, and USE=pcre support #389935.

(Portage version: 2.2.0_alpha72/cvs/Linux x86_64)

2 files changed, 64 insertions, 1 deletions

diff --git a/sys-apps/less/ChangeLog b/sys-apps/less/ChangeLog
index c6f54cf7b962..fc1d33cbe326 100644
--- a/sys-apps/less/ChangeLog
+++ b/sys-apps/less/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/less
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.131 2011/10/28 05:33:40 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.132 2011/11/09 18:43:05 vapier Exp $
+
+*less-445-r1 (09 Nov 2011)
+
+  09 Nov 2011; Mike Frysinger <vapier@gentoo.org> +less-445-r1.ebuild:
+  Update to EAPI=2, add editor-wrapper support, and USE=pcre support #389935.
 
 *less-445 (28 Oct 2011)
 
diff --git a/sys-apps/less/less-445-r1.ebuild b/sys-apps/less/less-445-r1.ebuild
new file mode 100644
index 000000000000..88fe4b8f3439
--- /dev/null
+++ b/sys-apps/less/less-445-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/less-445-r1.ebuild,v 1.1 2011/11/09 18:43:05 vapier Exp $
+
+EAPI="2"
+
+inherit eutils
+
+DESCRIPTION="Excellent text file viewer"
+HOMEPAGE="http://www.greenwoodsoftware.com/less/"
+SRC_URI="http://www.greenwoodsoftware.com/less/${P}.tar.gz
+	http://www-zeuthen.desy.de/~friebel/unix/less/code2color"
+
+LICENSE="|| ( GPL-3 BSD-2 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="pcre unicode"
+
+DEPEND="app-misc/editor-wrapper
+	>=sys-libs/ncurses-5.2
+	pcre? ( dev-libs/libpcre )"
+RDEPEND="${DEPEND}"
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	cp "${DISTDIR}"/code2color "${S}"/
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/code2color.patch
+}
+
+src_configure() {
+	export ac_cv_lib_ncursesw_initscr=$(usex unicode)
+	export ac_cv_lib_ncurses_initscr=$(usex !unicode)
+
+	local regex="posix"
+	use pcre && regex="pcre"
+
+	econf \
+		--with-regex=${regex} \
+		--with-editor=/usr/libexec/gentoo-editor
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+
+	dobin code2color || die "dobin"
+	newbin "${FILESDIR}"/lesspipe.sh lesspipe || die "newbin"
+	dosym lesspipe /usr/bin/lesspipe.sh
+	newenvd "${FILESDIR}"/less.envd 70less
+
+	dodoc NEWS README* "${FILESDIR}"/README.Gentoo
+}
+
+pkg_postinst() {
+	einfo "lesspipe offers colorization options.  Run 'lesspipe -h' for info."
+}