Make sure we respect LINGUAS #205952 by Arvid Norlander and version bump #211113.

(Portage version: 2.2_pre2)

4 files changed, 90 insertions, 4 deletions

diff --git a/sys-apps/attr/ChangeLog b/sys-apps/attr/ChangeLog
index dc0b39862ed2..17ab95469152 100644
--- a/sys-apps/attr/ChangeLog
+++ b/sys-apps/attr/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/attr
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/attr/ChangeLog,v 1.100 2007/11/19 06:36:02 kumba Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/attr/ChangeLog,v 1.101 2008/02/23 03:57:01 vapier Exp $
+
+*attr-2.4.41 (23 Feb 2008)
+
+  23 Feb 2008; Mike Frysinger <vapier@gentoo.org>
+  +files/attr-2.4.39-linguas.patch, attr-2.4.39.ebuild, +attr-2.4.41.ebuild:
+  Make sure we respect LINGUAS #205952 by Arvid Norlander and version bump
+  #211113.
 
   19 Nov 2007; Joshua Kinard <kumba@gentoo.org> attr-2.4.39.ebuild:
   Stable on mips, per #197204.
diff --git a/sys-apps/attr/attr-2.4.39.ebuild b/sys-apps/attr/attr-2.4.39.ebuild
index b2bb8040389f..41ec79c85c0e 100644
--- a/sys-apps/attr/attr-2.4.39.ebuild
+++ b/sys-apps/attr/attr-2.4.39.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2007 Gentoo Foundation
+# Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/attr/attr-2.4.39.ebuild,v 1.11 2007/12/11 10:18:34 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/attr/attr-2.4.39.ebuild,v 1.12 2008/02/23 03:57:01 vapier Exp $
 
 inherit eutils autotools toolchain-funcs
 
@@ -23,13 +23,18 @@ src_unpack() {
 	unpack ${A}
 	cd "${S}"
 	epatch "${FILESDIR}"/${PN}-2.4.39-gettext.patch
+	epatch "${FILESDIR}"/${PN}-2.4.39-linguas.patch #205948
 	epatch "${FILESDIR}"/${PN}-2.4.24-only-symlink-when-needed.patch
 	sed -i \
 		-e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
 		-e '/HAVE_ZIPPED_MANPAGES/s:=.*:=false:' \
 		include/builddefs.in \
 		|| die "failed to update builddefs"
+	# libtool will clobber install-sh which is really a custom file
+	mv install-sh acl.install-sh || die
 	AT_M4DIR="m4" eautoreconf
+	mv acl.install-sh install-sh || die
+	strip-linguas po
 }
 
 src_compile() {
diff --git a/sys-apps/attr/attr-2.4.41.ebuild b/sys-apps/attr/attr-2.4.41.ebuild
new file mode 100644
index 000000000000..b4fb47310b59
--- /dev/null
+++ b/sys-apps/attr/attr-2.4.41.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/attr/attr-2.4.41.ebuild,v 1.1 2008/02/23 03:57:01 vapier Exp $
+
+inherit eutils autotools toolchain-funcs
+
+MY_P="${PN}_${PV}-1"
+DESCRIPTION="Extended attributes tools"
+HOMEPAGE="http://oss.sgi.com/projects/xfs/"
+SRC_URI="ftp://oss.sgi.com/projects/xfs/download/cmd_tars/${MY_P}.tar.gz
+	ftp://xfs.org/mirror/SGI/cmd_tars/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="nls"
+
+DEPEND="nls? ( sys-devel/gettext )
+	sys-devel/autoconf"
+RDEPEND=""
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${PN}-2.4.39-gettext.patch
+	epatch "${FILESDIR}"/${PN}-2.4.39-linguas.patch #205948
+	epatch "${FILESDIR}"/${PN}-2.4.24-only-symlink-when-needed.patch
+	sed -i \
+		-e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
+		-e '/HAVE_ZIPPED_MANPAGES/s:=.*:=false:' \
+		include/builddefs.in \
+		|| die "failed to update builddefs"
+	# libtool will clobber install-sh which is really a custom file
+	mv install-sh acl.install-sh || die
+	AT_M4DIR="m4" eautoreconf
+	mv acl.install-sh install-sh || die
+	strip-linguas po
+}
+
+src_compile() {
+	unset PLATFORM #184564
+	export OPTIMIZER=${CFLAGS}
+	export DEBUG=-DNDEBUG
+
+	econf \
+		$(use_enable nls gettext) \
+		--libexecdir=/usr/$(get_libdir) \
+		--bindir=/bin \
+		|| die
+	emake || die
+}
+
+src_install() {
+	emake DIST_ROOT="${D}" install install-lib install-dev || die
+	# the man-pages packages provides the man2 files
+	rm -r "${D}"/usr/share/man/man2
+	prepalldocs
+
+	# move shared libs to /
+	dodir /$(get_libdir)
+	mv "${D}"/usr/$(get_libdir)/libattr.so* "${D}"/$(get_libdir)/ || die
+	gen_usr_ldscript libattr.so
+}
diff --git a/sys-apps/attr/files/attr-2.4.39-linguas.patch b/sys-apps/attr/files/attr-2.4.39-linguas.patch
new file mode 100644
index 000000000000..0c3ce5a97dde
--- /dev/null
+++ b/sys-apps/attr/files/attr-2.4.39-linguas.patch
@@ -0,0 +1,11 @@
+--- po/Makefile
++++ po/Makefile
+@@ -6,7 +6,7 @@
+ include $(TOPDIR)/include/builddefs
+ 
+ POTHEAD = $(PKG_NAME).pot
+-LINGUAS = de es fr gl nl pl sv
++LINGUAS ?= de es fr gl nl pl sv
+ LSRCFILES = $(LINGUAS:%=%.po) $(POTHEAD)
+ LDIRT = $(POTHEAD)
+