Revbump for EAPI5. Drop oldest revision

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 67C78E1D)

1 files changed, 52 insertions, 0 deletions

diff --git a/sys-auth/libnss-mysql/libnss-mysql-1.5_p20060915-r3.ebuild b/sys-auth/libnss-mysql/libnss-mysql-1.5_p20060915-r3.ebuild
new file mode 100644
index 000000000000..3ef92c166c52
--- /dev/null
+++ b/sys-auth/libnss-mysql/libnss-mysql-1.5_p20060915-r3.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/libnss-mysql/libnss-mysql-1.5_p20060915-r3.ebuild,v 1.1 2014/07/31 02:57:55 grknight Exp $
+
+EAPI=5
+
+inherit eutils multilib autotools
+
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+DESCRIPTION="NSS MySQL Library."
+HOMEPAGE="http://libnss-mysql.sourceforge.net/"
+SRC_URI="http://libnss-mysql.sourceforge.net/snapshot/${PN}-${PV/1.5_p/}.tgz"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="debug"
+
+DEPEND="virtual/mysql"
+RDEPEND="${DEPEND}"
+S="${WORKDIR}/${PN}"
+
+DOCS=( AUTHORS DEBUGGING FAQ INSTALL NEWS README THANKS
+	TODO UPGRADING ChangeLog
+)
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-no-automagic-debug.diff
+	eautoconf
+}
+
+src_configure() {
+	# Usually, authentication libraries don't belong into usr.
+	# But here, it's required that the lib is in the same dir
+	# as libmysql, because else failures may occur on boot if
+	# udev tries to access a user / group that doesn't exist
+	# on the system before /usr is mounted.
+	econf --libdir="/usr/$(get_libdir)" \
+		$(use_enable debug)
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete
+
+	newdoc sample/README README.sample
+
+	for subdir in sample/{linux,freebsd,complex,minimal} ; do
+		docinto "${subdir}"
+		dodoc "${subdir}/"{*.sql,*.cfg}
+	done
+}