revbump; add missing DEPs, fixes Bug #522964 by pinkbyte

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

4 files changed, 153 insertions, 5 deletions

diff --git a/sys-cluster/nova/ChangeLog b/sys-cluster/nova/ChangeLog
index db1d5c64aedb..519a35a134c7 100644
--- a/sys-cluster/nova/ChangeLog
+++ b/sys-cluster/nova/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/nova
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/nova/ChangeLog,v 1.73 2014/08/21 20:53:36 prometheanfire Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/nova/ChangeLog,v 1.74 2014/09/22 02:15:21 idella4 Exp $
+
+*nova-2014.1.2-r1 (22 Sep 2014)
+
+  22 Sep 2014; Ian Delaney <idella4@gentoo.org> +nova-2014.1.2-r1.ebuild,
+  nova-2014.1.9999.ebuild, nova-9999.ebuild:
+  revbump; add missing DEPs, fixes Bug #522964 by pinkbyte
 
 *nova-2014.1.2 (21 Aug 2014)
 
diff --git a/sys-cluster/nova/nova-2014.1.2-r1.ebuild b/sys-cluster/nova/nova-2014.1.2-r1.ebuild
new file mode 100644
index 000000000000..7940a17a6f92
--- /dev/null
+++ b/sys-cluster/nova/nova-2014.1.2-r1.ebuild
@@ -0,0 +1,138 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/nova/nova-2014.1.2-r1.ebuild,v 1.1 2014/09/22 02:15:21 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 eutils multilib user
+
+DESCRIPTION="A cloud computing fabric controller (main part of an IaaS system) written in Python"
+HOMEPAGE="https://launchpad.net/nova"
+SRC_URI="http://launchpad.net/${PN}/icehouse/${PV}/+download/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+compute +kvm +network +novncproxy sqlite mysql postgres xen"
+REQUIRED_USE="|| ( mysql postgres sqlite )
+			  compute? ( || ( kvm xen ) )"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+		>=dev-python/pbr-0.6[${PYTHON_USEDEP}]
+		<dev-python/pbr-1.0[${PYTHON_USEDEP}]
+		app-admin/sudo
+		dev-python/mox[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]"
+
+RDEPEND="sqlite? (
+			>=dev-python/sqlalchemy-0.8.0[sqlite,${PYTHON_USEDEP}]
+			!~dev-python/sqlalchemy-0.9.5[sqlite,${PYTHON_USEDEP}]
+	        <=dev-python/sqlalchemy-0.9.99[sqlite,${PYTHON_USEDEP}]
+		)
+		mysql? (
+			dev-python/mysql-python
+			>=dev-python/sqlalchemy-0.8.0[${PYTHON_USEDEP}]
+			!~dev-python/sqlalchemy-0.9.5[${PYTHON_USEDEP}]
+			<=dev-python/sqlalchemy-0.9.99[${PYTHON_USEDEP}]
+		)
+		postgres? (
+			dev-python/psycopg:2
+			>=dev-python/sqlalchemy-0.8.0[${PYTHON_USEDEP}]
+			!~dev-python/sqlalchemy-0.9.5[${PYTHON_USEDEP}]
+			<=dev-python/sqlalchemy-0.9.99[${PYTHON_USEDEP}]
+		)
+		>=dev-python/amqplib-0.6.1[${PYTHON_USEDEP}]
+		>=dev-python/anyjson-0.3.3[${PYTHON_USEDEP}]
+		>=dev-python/boto-2.12.0[${PYTHON_USEDEP}]
+		!~dev-python/boto-2.13.0[${PYTHON_USEDEP}]
+		>=dev-python/eventlet-0.13.0[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		>=dev-python/kombu-2.4.8[${PYTHON_USEDEP}]
+		>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
+		>=dev-python/routes-1.12.3-r1[${PYTHON_USEDEP}]
+		!~dev-python/routes-2.0[${PYTHON_USEDEP}]
+		>=dev-python/webob-1.2.3[${PYTHON_USEDEP}]
+		>=dev-python/greenlet-0.3.2[${PYTHON_USEDEP}]
+		>=dev-python/pastedeploy-1.5.0-r1[${PYTHON_USEDEP}]
+		dev-python/paste[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-migrate-0.8.2[${PYTHON_USEDEP}]
+		!~dev-python/sqlalchemy-migrate-0.8.4[${PYTHON_USEDEP}]
+		>=dev-python/netaddr-0.7.6[${PYTHON_USEDEP}]
+		>=dev-python/suds-0.4[${PYTHON_USEDEP}]
+		>=dev-python/paramiko-1.9.0[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+		>=dev-python/iso8601-0.1.9[${PYTHON_USEDEP}]
+		>=dev-python/python-cinderclient-1.0.6[${PYTHON_USEDEP}]
+		>=dev-python/python-neutronclient-2.3.4[${PYTHON_USEDEP}]
+		<=dev-python/python-neutronclient-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/python-glanceclient-0.9.0[${PYTHON_USEDEP}]
+		>=dev-python/python-keystoneclient-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/six-1.6.0[${PYTHON_USEDEP}]
+		>=dev-python/stevedore-0.14[${PYTHON_USEDEP}]
+		>=dev-python/websockify-0.5.1[${PYTHON_USEDEP}]
+		<dev-python/websockify-0.6[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-1.2.0[${PYTHON_USEDEP}]
+		dev-python/oslo-rootwrap[${PYTHON_USEDEP}]
+		>=dev-python/pycadf-0.4.1[${PYTHON_USEDEP}]
+		>=dev-python/oslo-messaging-1.3.0[${PYTHON_USEDEP}]
+		dev-python/libvirt-python[${PYTHON_USEDEP}]
+		novncproxy? ( www-apps/novnc )
+		sys-apps/iproute2
+		net-misc/openvswitch
+		net-misc/rabbitmq-server
+		sys-fs/sysfsutils
+		sys-fs/multipath-tools
+		kvm? ( app-emulation/qemu )
+		xen? ( app-emulation/xen
+			   app-emulation/xen-tools )"
+
+PATCHES=(
+)
+
+pkg_setup() {
+	enewgroup nova
+	enewuser nova -1 -1 /var/lib/nova nova
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	./tools/config/generate_sample.sh -b ./ -p nova -o etc/nova
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	for svc in api cert compute conductor consoleauth network scheduler spicehtml5proxy xvpvncproxy; do
+		newinitd "${FILESDIR}/nova.initd" "nova-${svc}"
+	done
+	use compute && newinitd "${FILESDIR}/nova.initd" "nova-compute"
+	use novncproxy && newinitd "${FILESDIR}/nova.initd" "nova-novncproxy"
+
+	diropts -m 0750 -o nova -g nova
+	dodir /var/log/nova /var/lib/nova/instances
+
+	insinto /etc/nova
+	insopts -m 0640 -o nova -g nova
+	newins "etc/nova/nova.conf.sample" "nova.conf"
+	doins "etc/nova/api-paste.ini"
+	doins "etc/nova/logging_sample.conf"
+	doins "etc/nova/policy.json"
+	doins "etc/nova/rootwrap.conf"
+	#rootwrap filters
+	insinto /etc/nova/rootwrap.d
+	doins "etc/nova/rootwrap.d/api-metadata.filters"
+	doins "etc/nova/rootwrap.d/compute.filters"
+	doins "etc/nova/rootwrap.d/network.filters"
+	#copy migration conf file (not coppied on install via setup.py script)
+	insinto /usr/$(get_libdir)/python2.7/site-packages/nova/db/sqlalchemy/migrate_repo/
+	doins "nova/db/sqlalchemy/migrate_repo/migrate.cfg"
+	#copy the CA cert dir (not coppied on install via setup.py script)
+	cp -R "${S}/nova/CA" "${D}/usr/$(get_libdir)/python2.7/site-packages/nova/" || die "installing CA files failed"
+
+	#add sudoers definitions for user nova
+	insinto /etc/sudoers.d/
+	insopts -m 0600 -o root -g root
+	doins "${FILESDIR}/nova-sudoers"
+}
diff --git a/sys-cluster/nova/nova-2014.1.9999.ebuild b/sys-cluster/nova/nova-2014.1.9999.ebuild
index c99f7d2b1298..d4f1ad120b4d 100644
--- a/sys-cluster/nova/nova-2014.1.9999.ebuild
+++ b/sys-cluster/nova/nova-2014.1.9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/nova/nova-2014.1.9999.ebuild,v 1.5 2014/08/10 20:21:07 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/nova/nova-2014.1.9999.ebuild,v 1.6 2014/09/22 02:15:21 idella4 Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python2_7 )
@@ -22,7 +22,9 @@ REQUIRED_USE="|| ( mysql postgres sqlite )
 DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
 		>=dev-python/pbr-0.6[${PYTHON_USEDEP}]
 		<dev-python/pbr-1.0[${PYTHON_USEDEP}]
-		app-admin/sudo"
+		app-admin/sudo
+		dev-python/mox[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]"
 
 RDEPEND="sqlite? (
 			>=dev-python/sqlalchemy-0.8.0[sqlite,${PYTHON_USEDEP}]
diff --git a/sys-cluster/nova/nova-9999.ebuild b/sys-cluster/nova/nova-9999.ebuild
index bc53a1ed607f..5c65a8810fa5 100644
--- a/sys-cluster/nova/nova-9999.ebuild
+++ b/sys-cluster/nova/nova-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/nova/nova-9999.ebuild,v 1.17 2014/08/10 20:21:07 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/nova/nova-9999.ebuild,v 1.18 2014/09/22 02:15:21 idella4 Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python2_7 )
@@ -21,7 +21,9 @@ REQUIRED_USE="|| ( mysql postgres sqlite )
 DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
 		>=dev-python/pbr-0.6[${PYTHON_USEDEP}]
 		<dev-python/pbr-1.0[${PYTHON_USEDEP}]
-		app-admin/sudo"
+		app-admin/sudo
+		dev-python/mox[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]"
 
 RDEPEND="sqlite? (
 			>=dev-python/sqlalchemy-0.8.0[sqlite,${PYTHON_USEDEP}]