Switch to virtual/udev in older ebuilds.

(Portage version: 2.1.11.59/cvs/Linux x86_64, signed Manifest commit with key F0134531E1DBFAB5)

11 files changed, 349 insertions, 18 deletions

diff --git a/sys-kernel/dracut/ChangeLog b/sys-kernel/dracut/ChangeLog
index 660ef3836e1a..1d8abc8de02f 100644
--- a/sys-kernel/dracut/ChangeLog
+++ b/sys-kernel/dracut/ChangeLog
@@ -1,6 +1,20 @@
 # ChangeLog for sys-kernel/dracut
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.115 2013/04/02 12:22:23 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/ChangeLog,v 1.116 2013/04/02 14:16:51 aidecoe Exp $
+
+  02 Apr 2013; Amadeusz Żołnowski <aidecoe@gentoo.org>
+  +files/026-0000-fix-version-print.patch, dracut-019-r6.ebuild,
+  dracut-022-r6.ebuild, dracut-023-r4.ebuild, dracut-024-r4.ebuild,
+  dracut-025.ebuild, dracut-026.ebuild, dracut-026-r1.ebuild,
+  +dracut-026-r2.ebuild, dracut-027.ebuild:
+  Switch to virtual/udev in older ebuilds.
+
+*dracut-026-r2 (02 Apr 2013)
+
+  02 Apr 2013; Amadeusz Żołnowski <aidecoe@gentoo.org>
+  +files/026-0000-fix-version-print.patch, +dracut-026-r2.ebuild:
+  Backporting changes wrt virtual/udev, CONFIG_MODULES and systemd from
+  dracut-027.ebuild.
 
 *dracut-027 (02 Apr 2013)
 
diff --git a/sys-kernel/dracut/dracut-019-r6.ebuild b/sys-kernel/dracut/dracut-019-r6.ebuild
index 8f8251c3feb3..ffd7a817817f 100644
--- a/sys-kernel/dracut/dracut-019-r6.ebuild
+++ b/sys-kernel/dracut/dracut-019-r6.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-019-r6.ebuild,v 1.5 2013/01/05 19:14:01 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-019-r6.ebuild,v 1.6 2013/04/02 14:16:51 aidecoe Exp $
 
 EAPI=4
 
@@ -67,8 +67,8 @@ RDEPEND="
 	|| ( >=sys-apps/module-init-tools-3.8 >sys-apps/kmod-5[tools] )
 	>=sys-apps/sysvinit-2.87-r3
 	>=sys-apps/util-linux-2.20
-	>=sys-fs/udev-166
 	virtual/pkgconfig
+	virtual/udev
 
 	debug? ( dev-util/strace )
 	device-mapper? ( || ( sys-fs/device-mapper >=sys-fs/lvm2-2.02.33 ) )
diff --git a/sys-kernel/dracut/dracut-022-r6.ebuild b/sys-kernel/dracut/dracut-022-r6.ebuild
index f85169fb0084..90b7341ee839 100644
--- a/sys-kernel/dracut/dracut-022-r6.ebuild
+++ b/sys-kernel/dracut/dracut-022-r6.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-022-r6.ebuild,v 1.5 2013/01/05 19:14:01 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-022-r6.ebuild,v 1.6 2013/04/02 14:16:51 aidecoe Exp $
 
 EAPI=4
 
@@ -59,7 +59,7 @@ IUSE="debug device-mapper optimization net selinux ${IUSE_DRACUT_MODULES}"
 
 RESTRICT="test"
 
-CDEPEND=">=sys-fs/udev-166"
+CDEPEND="virtual/udev"
 RDEPEND="${CDEPEND}
 	app-arch/cpio
 	>=app-shells/bash-4.0
diff --git a/sys-kernel/dracut/dracut-023-r4.ebuild b/sys-kernel/dracut/dracut-023-r4.ebuild
index 65bf2d58474b..4f30761a361d 100644
--- a/sys-kernel/dracut/dracut-023-r4.ebuild
+++ b/sys-kernel/dracut/dracut-023-r4.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-023-r4.ebuild,v 1.3 2013/01/05 19:14:01 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-023-r4.ebuild,v 1.4 2013/04/02 14:16:51 aidecoe Exp $
 
 EAPI=4
 
@@ -63,7 +63,7 @@ IUSE="debug device-mapper optimization net selinux ${IUSE_DRACUT_MODULES}"
 
 RESTRICT="test"
 
-CDEPEND=">sys-fs/udev-166
+CDEPEND="virtual/udev
 	dracut_modules_systemd? ( sys-apps/systemd )
 	"
 RDEPEND="${CDEPEND}
diff --git a/sys-kernel/dracut/dracut-024-r4.ebuild b/sys-kernel/dracut/dracut-024-r4.ebuild
index 6c6f2ab8bc4e..c9f4186a8a19 100644
--- a/sys-kernel/dracut/dracut-024-r4.ebuild
+++ b/sys-kernel/dracut/dracut-024-r4.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-024-r4.ebuild,v 1.3 2013/02/02 23:12:46 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-024-r4.ebuild,v 1.4 2013/04/02 14:16:51 aidecoe Exp $
 
 EAPI=4
 
@@ -63,7 +63,7 @@ IUSE="debug device-mapper optimization net selinux ${IUSE_DRACUT_MODULES}"
 
 RESTRICT="test"
 
-CDEPEND=">sys-fs/udev-166
+CDEPEND="virtual/udev
 	dracut_modules_systemd? ( sys-apps/systemd )
 	"
 RDEPEND="${CDEPEND}
diff --git a/sys-kernel/dracut/dracut-025.ebuild b/sys-kernel/dracut/dracut-025.ebuild
index 4be63d0fa1f0..9fb7b1b1376e 100644
--- a/sys-kernel/dracut/dracut-025.ebuild
+++ b/sys-kernel/dracut/dracut-025.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-025.ebuild,v 1.2 2013/03/10 09:56:34 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-025.ebuild,v 1.3 2013/04/02 14:16:51 aidecoe Exp $
 
 EAPI=4
 
@@ -63,7 +63,7 @@ IUSE="debug device-mapper optimization net selinux ${IUSE_DRACUT_MODULES}"
 
 RESTRICT="test"
 
-CDEPEND=">sys-fs/udev-166
+CDEPEND="virtual/udev
 	dracut_modules_systemd? ( sys-apps/systemd )
 	"
 RDEPEND="${CDEPEND}
diff --git a/sys-kernel/dracut/dracut-026-r1.ebuild b/sys-kernel/dracut/dracut-026-r1.ebuild
index d0064ba5d811..b5d89b5c647d 100644
--- a/sys-kernel/dracut/dracut-026-r1.ebuild
+++ b/sys-kernel/dracut/dracut-026-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-026-r1.ebuild,v 1.2 2013/03/30 16:25:08 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-026-r1.ebuild,v 1.3 2013/04/02 14:16:51 aidecoe Exp $
 
 EAPI=4
 
@@ -63,8 +63,8 @@ IUSE="debug device-mapper optimization net selinux ${IUSE_DRACUT_MODULES}"
 
 RESTRICT="test"
 
-CDEPEND="|| ( >sys-fs/udev-166 >=sys-apps/systemd-198-r5 )
-	dracut_modules_systemd? ( sys-apps/systemd )
+CDEPEND="virtual/udev
+	dracut_modules_systemd? ( >=sys-apps/systemd-198-r5 )
 	"
 RDEPEND="${CDEPEND}
 	app-arch/cpio
diff --git a/sys-kernel/dracut/dracut-026-r2.ebuild b/sys-kernel/dracut/dracut-026-r2.ebuild
new file mode 100644
index 000000000000..4cee330e2e98
--- /dev/null
+++ b/sys-kernel/dracut/dracut-026-r2.ebuild
@@ -0,0 +1,304 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-026-r2.ebuild,v 1.1 2013/04/02 14:16:51 aidecoe Exp $
+
+EAPI=4
+
+inherit eutils linux-info
+
+add_req_use_for() {
+	local dep="$1"; shift
+	local f
+
+	for f in "$@"; do
+		REQUIRED_USE+="${f}? ( ${dep} )
+"
+	done
+}
+
+DESCRIPTION="Generic initramfs generation tool"
+HOMEPAGE="http://dracut.wiki.kernel.org"
+SRC_URI="mirror://kernel/linux/utils/boot/${PN}/${P}.tar.bz2"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+REQUIRED_USE="
+	dracut_modules_bootchart? ( !dracut_modules_systemd )
+	dracut_modules_crypt-gpg? ( dracut_modules_crypt )
+	dracut_modules_crypt-loop? ( dracut_modules_crypt )
+	dracut_modules_livenet? ( dracut_modules_dmsquash-live )
+	"
+COMMON_MODULES="
+	dracut_modules_biosdevname
+	dracut_modules_bootchart
+	dracut_modules_btrfs
+	dracut_modules_caps
+	dracut_modules_crypt-gpg
+	dracut_modules_crypt-loop
+	dracut_modules_gensplash
+	dracut_modules_mdraid
+	dracut_modules_multipath
+	dracut_modules_plymouth
+	dracut_modules_syslog
+	dracut_modules_systemd
+	"
+DM_MODULES="
+	dracut_modules_crypt
+	dracut_modules_dmraid
+	dracut_modules_dmsquash-live
+	dracut_modules_livenet
+	dracut_modules_lvm
+	"
+NETWORK_MODULES="
+	dracut_modules_cifs
+	dracut_modules_iscsi
+	dracut_modules_livenet
+	dracut_modules_nbd
+	dracut_modules_nfs
+	dracut_modules_ssh-client
+	"
+add_req_use_for device-mapper ${DM_MODULES}
+add_req_use_for net ${NETWORK_MODULES}
+IUSE_DRACUT_MODULES="${COMMON_MODULES} ${DM_MODULES} ${NETWORK_MODULES}"
+IUSE="debug device-mapper optimization net selinux ${IUSE_DRACUT_MODULES}"
+
+RESTRICT="test"
+
+CDEPEND="virtual/udev
+	dracut_modules_systemd? ( >=sys-apps/systemd-198-r5 )
+	"
+RDEPEND="${CDEPEND}
+	app-arch/cpio
+	>=app-shells/bash-4.0
+	>=app-shells/dash-0.5.4.11
+	>=sys-apps/baselayout-1.12.14-r1
+	|| ( >=sys-apps/module-init-tools-3.8 >sys-apps/kmod-5[tools] )
+	>=sys-apps/sysvinit-2.87-r3
+	>=sys-apps/util-linux-2.21
+	virtual/pkgconfig
+
+	debug? ( dev-util/strace )
+	device-mapper? ( || ( sys-fs/device-mapper >=sys-fs/lvm2-2.02.33 ) )
+	net? ( net-misc/curl >=net-misc/dhcp-4.2.4_p2-r1[client] sys-apps/iproute2 )
+	selinux? ( sys-libs/libselinux sys-libs/libsepol )
+	dracut_modules_biosdevname? ( sys-apps/biosdevname )
+	dracut_modules_bootchart? ( app-benchmarks/bootchart2 sys-apps/usleep
+		sys-process/acct )
+	dracut_modules_btrfs? ( sys-fs/btrfs-progs )
+	dracut_modules_caps? ( sys-libs/libcap )
+	dracut_modules_cifs? ( net-fs/cifs-utils )
+	dracut_modules_crypt? ( sys-fs/cryptsetup )
+	dracut_modules_crypt-gpg? ( app-crypt/gnupg )
+	dracut_modules_dmraid? ( sys-fs/dmraid sys-fs/multipath-tools )
+	dracut_modules_gensplash? ( media-gfx/splashutils )
+	dracut_modules_iscsi? ( >=sys-block/open-iscsi-2.0.871.3 )
+	dracut_modules_lvm? ( >=sys-fs/lvm2-2.02.33 )
+	dracut_modules_mdraid? ( sys-fs/mdadm )
+	dracut_modules_multipath? ( sys-fs/multipath-tools )
+	dracut_modules_nbd? ( sys-block/nbd )
+	dracut_modules_nfs? ( net-fs/nfs-utils net-nds/rpcbind )
+	dracut_modules_plymouth? ( >=sys-boot/plymouth-0.8.3-r1 )
+	dracut_modules_ssh-client? ( dev-libs/openssl )
+	dracut_modules_syslog? ( || ( app-admin/syslog-ng app-admin/rsyslog ) )
+	"
+DEPEND="${CDEPEND}
+	app-text/asciidoc
+	>=dev-libs/libxslt-1.1.26
+	app-text/docbook-xml-dtd:4.5
+	>=app-text/docbook-xsl-stylesheets-1.75.2
+	"
+
+DOCS=( AUTHORS HACKING NEWS README README.generic README.kernel README.modules
+	README.testsuite TODO )
+MY_LIBDIR="/usr/lib"
+
+#
+# Helper functions
+#
+
+# Returns true if any of specified modules is enabled by USE flag and false
+# otherwise.
+# $1 = list of modules (which have corresponding USE flags of the same name)
+any_module() {
+	local m modules=" $@ "
+
+	for m in ${modules}; do
+		! use $m && modules=${modules/ $m / }
+	done
+
+	shopt -s extglob
+	modules=${modules%%+( )}
+	shopt -u extglob
+
+	[[ ${modules} ]]
+}
+
+# Removes module from modules.d.
+# $1 = module name
+# Module name can be specified without number prefix.
+rm_module() {
+	local force m
+	[[ $1 = -f ]] && force=-f
+
+	for m in $@; do
+		if [[ $m =~ ^[0-9][0-9][^\ ]*$ ]]; then
+			rm ${force} --interactive=never -r "${modules_dir}"/$m
+		else
+			rm ${force} --interactive=never -r "${modules_dir}"/[0-9][0-9]$m
+		fi
+	done
+}
+
+#
+# ebuild functions
+#
+
+src_prepare() {
+	epatch "${FILESDIR}/${PV}-0000-fix-version-print.patch"
+	epatch "${FILESDIR}/${PV}-0001-dracut-functions.sh-support-for-altern.patch"
+	epatch "${FILESDIR}/${PV}-0002-gentoo.conf-let-udevdir-be-handled-by-.patch"
+	epatch "${FILESDIR}/${PV}-0004-lsinitrd.sh-fix-for-default-initrd-not.patch"
+	epatch "${FILESDIR}/${PV}-0005-lsinitrd.sh-removed-trailing.patch"
+	epatch "${FILESDIR}/${PV}-0006-make-host_fs_types-a-hashmap.patch"
+	chmod +x "${S}/modules.d/95udev-rules/udev-rules-prepare.sh"
+
+	if use dracut_modules_systemd; then
+		local systemdutildir="$($(tc-getPKG_CONFIG) systemd \
+			--variable=systemdutildir)"
+		local systemdsystemunitdir="$($(tc-getPKG_CONFIG) systemd \
+			--variable=systemdsystemunitdir)"
+		[[ ${systemdutildir} ]] || die "Couldn't detect systemdutildir"
+		[[ ${systemdsystemunitdir} ]] \
+			|| die "Couldn't detect systemdsystemunitdir"
+		einfo "Setting systemdutildir to ${systemdutildir} and ..."
+		sed -e "4asystemdutildir=\"${systemdutildir}\"" \
+			-i "${S}/dracut.conf.d/gentoo.conf.example" || die
+		einfo "Setting systemdsystemunitdir to ${systemdsystemunitdir}..."
+		sed -e "5asystemdsystemunitdir=\"${systemdsystemunitdir}\"" \
+			-i "${S}/dracut.conf.d/gentoo.conf.example" || die
+	fi
+}
+
+src_configure() {
+	econf --libdir="${MY_LIBDIR}"
+}
+
+src_compile() {
+	emake doc
+
+	if use optimization; then
+		ewarn "Enabling experimental optimization!"
+		tc-export CC
+		emake install/dracut-install
+	fi
+}
+
+src_install() {
+	default
+
+	local libdir="${DRACUT_LIBDIR}"
+
+	local dracutlibdir="${MY_LIBDIR#/}/dracut"
+
+	echo "DRACUT_VERSION=$PVR" > "${D%/}/${dracutlibdir}/dracut-version.sh"
+
+	insinto "${dracutlibdir}/dracut.conf.d/"
+	newins dracut.conf.d/gentoo.conf.example gentoo.conf
+
+	insinto /etc/logrotate.d
+	newins dracut.logrotate dracut
+
+	dodir /var/lib/dracut/overlay
+
+	dohtml dracut.html
+
+	#
+	# Modules
+	#
+	local module
+	modules_dir="${D%/}/${dracutlibdir}/modules.d"
+
+	# Remove modules not enabled by USE flags
+	for module in ${IUSE_DRACUT_MODULES} ; do
+		! use ${module} && rm_module -f ${module#dracut_modules_}
+	done
+
+	# Those flags are specific, and even are corresponding to modules, they need
+	# to be declared as regular USE flags.
+	use debug || rm_module 95debug
+	use selinux || rm_module 98selinux
+
+	# Following flags define set of helper modules which are base dependencies
+	# for others and as so have no practical use, so remove these modules.
+	use device-mapper  || rm_module 90dm
+	use net || rm_module 40network 45ifcfg 45url-lib
+
+	if use dracut_modules_systemd; then
+		# With systemd following modules do not make sense
+		rm_module 96securityfs 98selinux
+	else
+		# Without systemd following modules do not make sense
+		rm_module 00systemd-bootchart
+	fi
+
+	# Remove S/390 modules which are not tested at all
+	rm_module 80cms 95dasd 95dasd_mod 95zfcp 95znet
+
+	# Remove modules which won't work for sure
+	rm_module 95fcoe # no tools
+	# fips module depends on masked app-crypt/hmaccalc
+	rm_module 01fips 02fips-aesni
+
+	# Remove extra modules which go to future dracut-extras
+	rm_module 05busybox 97masterkey 98ecryptfs 98integrity
+}
+
+pkg_postinst() {
+	if linux-info_get_any_version && linux_config_src_exists; then
+		ewarn ""
+		ewarn "If the following test report contains a missing kernel"
+		ewarn "configuration option, you should reconfigure and rebuild your"
+		ewarn "kernel before booting image generated with this Dracut version."
+		ewarn ""
+
+		local CONFIG_CHECK="~BLK_DEV_INITRD ~DEVTMPFS"
+
+		# Kernel configuration options descriptions:
+		local desc_DEVTMPFS="Maintain a devtmpfs filesystem to mount at /dev"
+		local desc_BLK_DEV_INITRD="Initial RAM filesystem and RAM disk "\
+"(initramfs/initrd) support"
+
+		local opt desc
+
+		# Generate ERROR_* variables for check_extra_config.
+		for opt in ${CONFIG_CHECK}; do
+			opt=${opt#\~}
+			desc=desc_${opt}
+			eval "local ERROR_${opt}='CONFIG_${opt}: \"${!desc}\"" \
+				"is missing and REQUIRED'"
+		done
+
+		check_extra_config
+		echo
+	else
+		ewarn ""
+		ewarn "Your kernel configuration couldn't be checked.  Do you have"
+		ewarn "/usr/src/linux/.config file there?  Please check manually if"
+		ewarn "following options are enabled:"
+		ewarn ""
+		ewarn "  CONFIG_BLK_DEV_INITRD"
+		ewarn "  CONFIG_DEVTMPFS"
+		ewarn ""
+	fi
+
+	if use dracut_modules_crypt || use dracut_modules_dmraid || use \
+		dracut_modules_mdraid || use dracut_modules_lvm; then
+
+		if ! [[ $(</proc/cmdline) =~ rd.auto[\ =] ]]; then
+			ewarn "Autoassembly of special devices like cryptoLUKS, dmraid, "
+			ewarn "mdraid or lvm is off for default as of  >=dracut-024."
+			ewarn "Use rd.auto option to turn it on."
+		fi
+	fi
+}
diff --git a/sys-kernel/dracut/dracut-026.ebuild b/sys-kernel/dracut/dracut-026.ebuild
index f350e5b3184a..212dcf8a6f56 100644
--- a/sys-kernel/dracut/dracut-026.ebuild
+++ b/sys-kernel/dracut/dracut-026.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-026.ebuild,v 1.1 2013/03/10 14:09:35 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-026.ebuild,v 1.2 2013/04/02 14:16:51 aidecoe Exp $
 
 EAPI=4
 
@@ -63,7 +63,7 @@ IUSE="debug device-mapper optimization net selinux ${IUSE_DRACUT_MODULES}"
 
 RESTRICT="test"
 
-CDEPEND=">sys-fs/udev-166
+CDEPEND="virtual/udev
 	dracut_modules_systemd? ( sys-apps/systemd )
 	"
 RDEPEND="${CDEPEND}
diff --git a/sys-kernel/dracut/dracut-027.ebuild b/sys-kernel/dracut/dracut-027.ebuild
index b7cccdcb697a..8ea829521740 100644
--- a/sys-kernel/dracut/dracut-027.ebuild
+++ b/sys-kernel/dracut/dracut-027.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-027.ebuild,v 1.1 2013/04/02 12:22:23 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/dracut/dracut-027.ebuild,v 1.2 2013/04/02 14:16:51 aidecoe Exp $
 
 EAPI=4
 
@@ -65,7 +65,7 @@ IUSE="debug device-mapper optimization net selinux ${IUSE_DRACUT_MODULES}"
 
 RESTRICT="test"
 
-CDEPEND="|| ( virtual/udev )
+CDEPEND="virtual/udev
 	dracut_modules_systemd? ( >=sys-apps/systemd-199 )
 	"
 RDEPEND="${CDEPEND}
diff --git a/sys-kernel/dracut/files/026-0000-fix-version-print.patch b/sys-kernel/dracut/files/026-0000-fix-version-print.patch
new file mode 100644
index 000000000000..3607fb24552c
--- /dev/null
+++ b/sys-kernel/dracut/files/026-0000-fix-version-print.patch
@@ -0,0 +1,13 @@
+diff --git a/modules.d/99base/init.sh b/modules.d/99base/init.sh
+index b441a27..410201a 100755
+--- a/modules.d/99base/init.sh
++++ b/modules.d/99base/init.sh
+@@ -104,7 +104,7 @@ else
+ fi
+ 
+ [ -f /etc/initrd-release ] && . /etc/initrd-release
+-[ -n "$VERSION" ] && info "dracut-$VERSION"
++[ -n "$VERSION_ID" ] && info "$NAME-$VERSION_ID"
+ 
+ source_conf /etc/conf.d
+