New upstream release.

(Portage version: 2.1.2-r9)

1 files changed, 57 insertions, 0 deletions

diff --git a/sys-libs/libselinux/libselinux-1.34.0.ebuild b/sys-libs/libselinux/libselinux-1.34.0.ebuild
new file mode 100644
index 000000000000..5f6a078a33d0
--- /dev/null
+++ b/sys-libs/libselinux/libselinux-1.34.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/libselinux/libselinux-1.34.0.ebuild,v 1.1 2007/02/15 05:23:51 pebenito Exp $
+
+IUSE=""
+
+inherit eutils multilib python
+
+#BUGFIX_PATCH="${FILESDIR}/libselinux-1.30.3.diff"
+
+SEPOL_VER="1.16"
+
+DESCRIPTION="SELinux userland library"
+HOMEPAGE="http://www.nsa.gov/selinux"
+SRC_URI="http://www.nsa.gov/selinux/archives/${P}.tgz"
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~mips ~ppc ~sparc ~x86"
+
+DEPEND="=sys-libs/libsepol-${SEPOL_VER}*"
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}
+
+	[ ! -z "${BUGFIX_PATCH}" ] && epatch "${BUGFIX_PATCH}"
+
+	# fix up paths for multilib
+	sed -i -e "/^LIBDIR/s/lib/$(get_libdir)/" ${S}/src/Makefile \
+		|| die "Fix for multilib LIBDIR failed."
+	sed -i -e "/^SHLIBDIR/s/lib/$(get_libdir)/" ${S}/src/Makefile \
+		|| die "Fix for multilib SHLIBDIR failed."
+}
+
+src_compile() {
+	python_version
+	emake LDFLAGS="-fPIC ${LDFLAGS}" all || die
+	emake PYLIBVER="python${PYVER}" LDFLAGS="-fPIC ${LDFLAGS}" pywrap || die
+
+	# add compatability aliases to swig wrapper
+	cat ${FILESDIR}/compat.py >> ${S}/src/selinux.py || die
+}
+
+src_install() {
+	python_version
+	make DESTDIR="${D}" PYLIBVER="python${PYVER}" install install-pywrap || die
+}
+
+pkg_postinst() {
+	python_version
+	python_mod_optimize ${ROOT}usr/lib/python${PYVER}/site-packages
+}
+
+pkg_postrm() {
+	python_version
+	python_mod_cleanup ${ROOT}usr/lib/python${PYVER}/site-packages
+}