version bump, mark stable

(Portage version: 2.1.11.31/cvs/Linux x86_64, signed Manifest commit with key 27F4B742)

1 files changed, 64 insertions, 0 deletions

diff --git a/www-apps/dokuwiki/dokuwiki-20121013.ebuild b/www-apps/dokuwiki/dokuwiki-20121013.ebuild
new file mode 100644
index 000000000000..e0ac1a41471c
--- /dev/null
+++ b/www-apps/dokuwiki/dokuwiki-20121013.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/dokuwiki-20121013.ebuild,v 1.1 2012/12/24 08:14:04 ramereth Exp $
+
+EAPI="4"
+
+inherit webapp depend.php
+
+# upstream uses dashes in the datestamp
+MY_BASE_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PV="${MY_BASE_PV}${PV:8:1}"
+
+DESCRIPTION="DokuWiki is a simple to use Wiki aimed at a small company's documentation needs."
+HOMEPAGE="http://wiki.splitbrain.org/wiki:dokuwiki"
+SRC_URI="http://www.splitbrain.org/_media/projects/${PN}/${PN}-${MY_PV}.tgz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="gd"
+
+DEPEND=""
+RDEPEND="
+	>=dev-lang/php-5.3[xml]
+	gd? ( || ( dev-lang/php[gd]
+		media-gfx/imagemagick )
+	)"
+
+need_httpd_cgi
+need_php_httpd
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+src_prepare() {
+	# create initial changes file
+	touch data/changes.log
+}
+
+src_install() {
+	webapp_src_preinst
+
+	dodoc README
+	rm -f README COPYING
+
+	docinto scripts
+	dodoc bin/*
+	rm -rf bin
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	for x in $(find data/ -not -name '.htaccess'); do
+		webapp_serverowned "${MY_HTDOCSDIR}"/${x}
+	done
+
+	webapp_configfile "${MY_HTDOCSDIR}"/.htaccess.dist
+	webapp_configfile "${MY_HTDOCSDIR}"/conf
+
+	for x in $(find conf/ -not -name 'msg'); do
+		webapp_configfile "${MY_HTDOCSDIR}"/${x}
+	done
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+	webapp_src_install
+}