Add new snapshot, support firefox as alternative dependency. Remove old.

(Portage version: 2.1.10.49/cvs/Linux x86_64)

1 files changed, 63 insertions, 0 deletions

diff --git a/www-client/conkeror/conkeror-1.0_pre20120223.ebuild b/www-client/conkeror/conkeror-1.0_pre20120223.ebuild
new file mode 100644
index 000000000000..79b501e0d1ca
--- /dev/null
+++ b/www-client/conkeror/conkeror-1.0_pre20120223.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/conkeror/conkeror-1.0_pre20120223.ebuild,v 1.1 2012/03/24 17:41:47 ulm Exp $
+
+EAPI=4
+
+inherit eutils fdo-mime
+
+DESCRIPTION="A Mozilla-based web browser whose design is inspired by GNU Emacs"
+HOMEPAGE="http://conkeror.org/"
+# snapshot from http://repo.or.cz/w/conkeror.git
+# conkeror.png is derived from http://commons.wikimedia.org/wiki/File:Conker.jpg
+SRC_URI="mirror://gentoo/${P}.tar.gz
+	mirror://gentoo/conkeror.png"
+
+# CC-BY-SA-3.0 for conkeror.png
+LICENSE="|| ( MPL-1.1 GPL-2 LGPL-2.1 ) CCPL-Attribution-ShareAlike-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+DEPEND=""
+RDEPEND="|| ( >=net-libs/xulrunner-1.9.1
+		>=www-client/firefox-5.0
+		>=www-client/firefox-bin-5.0 )"
+
+S="${WORKDIR}/${PN}"
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	cp "${DISTDIR}/conkeror.png" . || die
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	insinto /usr/share/${PN}
+	doins -r branding chrome components content defaults help locale modules \
+		search-engines style tests
+	doins application.ini chrome.manifest Info.plist
+
+	exeinto /usr/libexec/${PN}
+	doexe conkeror-spawn-helper
+	dosym ../../libexec/${PN}/conkeror-spawn-helper \
+		/usr/share/${PN}/conkeror-spawn-helper
+
+	newbin "${FILESDIR}/conkeror.sh" conkeror
+	domenu "${FILESDIR}/conkeror.desktop"
+	doicon "${WORKDIR}/conkeror.png"
+
+	doman contrib/man/conkeror.1
+	dodoc CREDITS
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}