Version bump.

(Portage version: 2.2.6/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 132 insertions, 1 deletions

diff --git a/www-client/links/ChangeLog b/www-client/links/ChangeLog
index d132338138c6..ffe680b1819d 100644
--- a/www-client/links/ChangeLog
+++ b/www-client/links/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/links
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/links/ChangeLog,v 1.190 2013/08/27 15:09:06 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/links/ChangeLog,v 1.191 2013/09/23 09:45:58 ssuominen Exp $
+
+*links-2.8 (23 Sep 2013)
+
+  23 Sep 2013; Samuli Suominen <ssuominen@gentoo.org> +links-2.8.ebuild:
+  Version bump.
 
   27 Aug 2013; Michael Palimaka <kensington@gentoo.org> links-2.7.ebuild:
   Pin virtual/jpeg SLOT to 0.
diff --git a/www-client/links/links-2.8.ebuild b/www-client/links/links-2.8.ebuild
new file mode 100644
index 000000000000..1ea79ee79e93
--- /dev/null
+++ b/www-client/links/links-2.8.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/links/links-2.8.ebuild,v 1.1 2013/09/23 09:45:58 ssuominen Exp $
+
+EAPI=5
+inherit autotools eutils fdo-mime
+
+DESCRIPTION="A fast and lightweight web browser running in both graphics and text mode"
+HOMEPAGE="http://links.twibright.com/"
+SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 directfb fbcon gpm ipv6 jpeg livecd lzma ssl suid svga tiff unicode X zlib"
+
+GRAPHICS_DEPEND="media-libs/libpng:0="
+
+RDEPEND=">=sys-libs/ncurses-5.7-r7
+	bzip2? ( app-arch/bzip2 )
+	directfb? (
+		${GRAPHICS_DEPEND}
+		dev-libs/DirectFB
+		)
+	fbcon? ( ${GRAPHICS_DEPEND} )
+	gpm? ( sys-libs/gpm )
+	jpeg? ( virtual/jpeg:0 )
+	livecd? (
+		${GRAPHICS_DEPEND}
+		sys-libs/gpm
+		virtual/jpeg:0
+		)
+	lzma? ( app-arch/xz-utils )
+	ssl? ( dev-libs/openssl:0 )
+	svga? (
+		${GRAPHICS_DEPEND}
+		media-libs/svgalib
+		)
+	tiff? ( media-libs/tiff:0 )
+	X? (
+		${GRAPHICS_DEPEND}
+		x11-libs/libXext
+		)
+	zlib? ( sys-libs/zlib )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	fbcon? ( virtual/os-headers )
+	livecd? ( virtual/os-headers )"
+
+REQUIRED_USE="!livecd? ( fbcon? ( gpm ) )
+	svga? ( suid )"
+
+DOCS=( AUTHORS BRAILLE_HOWTO ChangeLog KEYS NEWS README SITES )
+
+src_prepare() {
+	if use unicode; then
+		pushd intl >/dev/null
+		./gen-intl || die
+		./synclang || die
+		popd >/dev/null
+	fi
+
+	# error: conditional "am__fastdepCXX" was never defined (for eautoreconf)
+	sed -i \
+		-e '/AC_PROG_CXX/s:dnl ::' \
+		-e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' \
+		configure.in || die #467020
+
+	# Upstream configure produced by broken autoconf-2.13. This also fixes
+	# toolchain detection.
+	eautoreconf #131440 and #103483#c23
+}
+
+src_configure() {
+	local myconf
+
+	if use livecd; then
+		export ac_cv_lib_gpm_Gpm_Open=yes
+		myconf+=' --with-fb --with-libjpeg'
+	else
+		export ac_cv_lib_gpm_Gpm_Open=$(usex gpm)
+	fi
+
+	if use X || use fbcon || use directfb || use svga || use livecd; then
+		myconf+=' --enable-graphics'
+	fi
+
+	econf \
+		$(use_with ipv6) \
+		$(use_with ssl) \
+		$(use_with zlib) \
+		$(use_with bzip2) \
+		$(use_with lzma) \
+		$(use_with svga svgalib) \
+		$(use_with X x) \
+		$(use_with fbcon fb) \
+		$(use_with directfb) \
+		$(use_with jpeg libjpeg) \
+		$(use_with tiff libtiff) \
+		${myconf}
+}
+
+src_install() {
+	default
+
+	if use X; then
+		newicon Links_logo.png links.png
+		make_desktop_entry 'links -g %u' Links links 'Network;WebBrowser'
+		local d="${ED}"/usr/share/applications
+		echo 'MimeType=x-scheme-handler/http;' >> "${d}"/*.desktop
+		use ssl && sed -i -e 's:x-scheme-handler/http;:&x-scheme-handler/https;:' \
+			"${d}"/*.desktop
+	fi
+
+	nonfatal dohtml doc/links_cal/*
+	use suid && fperms 4755 /usr/bin/links
+}
+
+pkg_postinst() {
+	use X && fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	use X && fdo-mime_desktop_database_update
+}