Version bump.

(Portage version: 2.2.0_alpha111/cvs/Linux x86_64)

2 files changed, 129 insertions, 1 deletions

diff --git a/www-client/links/ChangeLog b/www-client/links/ChangeLog
index a8cf776518dd..ac9e2c2babea 100644
--- a/www-client/links/ChangeLog
+++ b/www-client/links/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/links
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/links/ChangeLog,v 1.177 2012/05/09 00:32:19 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/links/ChangeLog,v 1.178 2012/06/26 14:20:09 ssuominen Exp $
+
+*links-2.7 (26 Jun 2012)
+
+  26 Jun 2012; Samuli Suominen <ssuominen@gentoo.org> +links-2.7.ebuild:
+  Version bump.
 
   09 May 2012; Alexis Ballier <aballier@gentoo.org> links-2.6.ebuild:
   keyword ~amd64-fbsd
diff --git a/www-client/links/links-2.7.ebuild b/www-client/links/links-2.7.ebuild
new file mode 100644
index 000000000000..777c73e79789
--- /dev/null
+++ b/www-client/links/links-2.7.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/links/links-2.7.ebuild,v 1.1 2012/06/26 14:20:09 ssuominen Exp $
+
+EAPI=4
+inherit autotools eutils fdo-mime
+
+DESCRIPTION="A fast and lightweight web browser running in both graphics and text mode"
+HOMEPAGE="http://links.twibright.com/"
+SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2
+	mirror://debian/pool/main/${PN:0:1}/${PN}2/${PN}2_2.6-2.debian.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 +deprecated directfb fbcon gpm jpeg livecd lzma ssl suid svga tiff unicode X zlib"
+
+GRAPHICS_DEPEND=">=media-libs/libpng-1.2:0" #75685
+
+RDEPEND=">=sys-libs/ncurses-5.7-r7
+	bzip2? ( app-arch/bzip2 )
+	directfb? ( dev-libs/DirectFB )
+	fbcon? ( ${GRAPHICS_DEPEND} )
+	gpm? ( sys-libs/gpm )
+	jpeg? ( virtual/jpeg )
+	livecd? (
+		${GRAPHICS_DEPEND}
+		sys-libs/gpm
+		virtual/jpeg
+		)
+	lzma? ( app-arch/xz-utils )
+	ssl? ( dev-libs/openssl:0 )
+	svga? (
+		${GRAPHICS_DEPEND}
+		>=media-libs/svgalib-1.4.3
+		)
+	tiff? ( media-libs/tiff:0 )
+	X? (
+		${GRAPHICS_DEPEND}
+		x11-libs/libXext
+		)
+	zlib? ( sys-libs/zlib )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	fbcon? ( virtual/os-headers )
+	livecd? ( virtual/os-headers )"
+
+REQUIRED_USE="!livecd? ( fbcon? ( gpm ) )
+	svga? ( suid )"
+
+DOCS=( AUTHORS BRAILLE_HOWTO ChangeLog KEYS NEWS README SITES )
+
+src_prepare() {
+	epatch "${WORKDIR}"/debian/patches/verify-ssl-certs-510417.diff
+
+	if use unicode; then
+		pushd intl >/dev/null
+		./gen-intl || die
+		./synclang || die
+		popd >/dev/null
+	fi
+
+	# error: conditional "am__fastdepCXX" was never defined (for eautoreconf)
+	sed -i -e '/AC_PROG_CXX/s:#::' configure.in || die
+
+	# Upstream configure produced by broken autoconf-2.13. This also fixes
+	# toolchain detection.
+	eautoreconf #131440 and #103483#c23
+}
+
+src_configure() {
+	local myconf
+
+	if use livecd; then
+		export ac_cv_lib_gpm_Gpm_Open=yes
+		myconf+=' --with-fb --with-libjpeg'
+	else
+		export ac_cv_lib_gpm_Gpm_Open=$(usex gpm)
+	fi
+
+	if use X || use fbcon || use directfb || use svga || use livecd; then
+		myconf+=' --enable-graphics'
+	fi
+
+	econf \
+		$(use_with ssl) \
+		$(use_with zlib) \
+		$(use_with bzip2) \
+		$(use_with lzma) \
+		$(use_with svga svgalib) \
+		$(use_with X x) \
+		$(use_with fbcon fb) \
+		$(use_with directfb) \
+		$(use_with jpeg libjpeg) \
+		$(use_with tiff libtiff) \
+		${myconf}
+}
+
+src_install() {
+	default
+
+	if use X; then
+		newicon Links_logo.png links.png
+		make_desktop_entry 'links -g %u' Links links 'Network;WebBrowser'
+		local d="${ED}"/usr/share/applications
+		echo 'MimeType=x-scheme-handler/http;' >> "${d}"/*.desktop
+		use ssl && sed -i -e 's:x-scheme-handler/http;:&x-scheme-handler/https;:' \
+			"${d}"/*.desktop
+	fi
+
+	nonfatal dohtml doc/links_cal/*
+	use deprecated && dosym links /usr/bin/links2
+	use suid && fperms 4755 /usr/bin/links
+}
+
+pkg_postinst() {
+	use X && fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	use X && fdo-mime_desktop_database_update
+}