Use new python eclasses, bump EAPI and comply with gnome2.eclass policies

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 59 insertions, 1 deletions

diff --git a/x11-libs/hippo-canvas/ChangeLog b/x11-libs/hippo-canvas/ChangeLog
index e2bd378c67a4..054cfa54f934 100644
--- a/x11-libs/hippo-canvas/ChangeLog
+++ b/x11-libs/hippo-canvas/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/hippo-canvas
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/hippo-canvas/ChangeLog,v 1.10 2014/02/16 10:37:32 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/hippo-canvas/ChangeLog,v 1.11 2014/11/21 12:39:37 pacho Exp $
+
+*hippo-canvas-0.3.0-r2 (21 Nov 2014)
+
+  21 Nov 2014; Pacho Ramos <pacho@gentoo.org> +hippo-canvas-0.3.0-r2.ebuild:
+  Use new python eclasses, bump EAPI and comply with gnome2.eclass policies
 
   16 Feb 2014; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Cleanup due #200380
diff --git a/x11-libs/hippo-canvas/hippo-canvas-0.3.0-r2.ebuild b/x11-libs/hippo-canvas/hippo-canvas-0.3.0-r2.ebuild
new file mode 100644
index 000000000000..9b5b9d4c809e
--- /dev/null
+++ b/x11-libs/hippo-canvas/hippo-canvas-0.3.0-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/hippo-canvas/hippo-canvas-0.3.0-r2.ebuild,v 1.1 2014/11/21 12:39:37 pacho Exp $
+
+EAPI=5
+GCONF_DEBUG="no"
+GNOME_TARBALL_SUFFIX="bz2"
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+
+inherit eutils gnome2 multilib python-single-r1
+
+DESCRIPTION="A canvas library based on GTK+ 2, Cairo, and Pango"
+HOMEPAGE="https://wiki.gnome.org/Projects/HippoCanvas"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-libs/glib-2.6:2
+	dev-libs/libcroco
+	>=x11-libs/gtk+-2.6:2
+	x11-libs/pango
+	gnome-base/librsvg:2
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygtk:2[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cd "${S}/python"
+	epatch "${FILESDIR}/${PN}-python-override.patch"
+	cd "${S}"
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable python)
+}