version bump

(Portage version: 2.2.0_alpha137/cvs/Linux x86_64)

2 files changed, 80 insertions, 1 deletions

diff --git a/x11-libs/libva/ChangeLog b/x11-libs/libva/ChangeLog
index a75f3294b351..150b955acf29 100644
--- a/x11-libs/libva/ChangeLog
+++ b/x11-libs/libva/ChangeLog
@@ -1,6 +1,9 @@
 # ChangeLog for x11-libs/libva
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva/ChangeLog,v 1.41 2012/10/11 12:05:49 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva/ChangeLog,v 1.42 2012/10/11 12:33:13 aballier Exp $
+
+  11 Oct 2012; Alexis Ballier <aballier@gentoo.org> +libva-1.1.0.ebuild:
+  version bump
 
   11 Oct 2012; Alexis Ballier <aballier@gentoo.org> libva-9999.ebuild,
   metadata.xml:
diff --git a/x11-libs/libva/libva-1.1.0.ebuild b/x11-libs/libva/libva-1.1.0.ebuild
new file mode 100644
index 000000000000..e9cfcd749606
--- /dev/null
+++ b/x11-libs/libva/libva-1.1.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva/libva-1.1.0.ebuild,v 1.4 2012/10/11 12:33:13 aballier Exp $
+
+EAPI=4
+
+SCM=""
+if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
+	SCM=git-2
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="git://anongit.freedesktop.org/vaapi/libva"
+fi
+
+inherit autotools ${SCM} multilib
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/vaapi"
+if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
+	SRC_URI=""
+	S="${WORKDIR}/${PN}"
+else
+	SRC_URI="http://cgit.freedesktop.org/vaapi/libva/snapshot/${P}.tar.bz2"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+if [ "${PV%9999}" = "${PV}" ] ; then
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+else
+	KEYWORDS=""
+fi
+IUSE="egl opengl wayland X"
+
+VIDEO_CARDS="dummy nvidia intel fglrx"
+for x in ${VIDEO_CARDS}; do
+	IUSE+=" video_cards_${x}"
+done
+
+RDEPEND=">=x11-libs/libdrm-2.4
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXfixes
+	)
+	egl? ( media-libs/mesa[egl] )
+	opengl? ( virtual/opengl )
+	wayland? ( >=dev-libs/wayland-0.95.0 )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+PDEPEND="video_cards_nvidia? ( x11-libs/vdpau-video )
+	video_cards_fglrx? ( x11-libs/xvba-video )
+	video_cards_intel? ( >=x11-libs/libva-intel-driver-1.0.18 )
+	"
+
+REQUIRED_USE="opengl? ( X )"
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-drivers-path="${EPREFIX}/usr/$(get_libdir)/va/drivers" \
+		$(use_enable video_cards_dummy dummy-driver) \
+		$(use_enable opengl glx) \
+		$(use_enable X x11) \
+		$(use_enable wayland) \
+		$(use_enable egl)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc NEWS || die
+	find "${D}" -name '*.la' -delete
+}