Version bump (bug #457030 by teidakankan). Do not install useless NEWS.

(Portage version: 2.2.0_alpha162/cvs/Linux x86_64, signed Manifest commit with key A792A613)

3 files changed, 85 insertions, 5 deletions

diff --git a/x11-misc/xfe/ChangeLog b/x11-misc/xfe/ChangeLog
index d41be8115460..eda8086d1e64 100644
--- a/x11-misc/xfe/ChangeLog
+++ b/x11-misc/xfe/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-misc/xfe
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xfe/ChangeLog,v 1.84 2012/12/28 11:09:50 ago Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xfe/ChangeLog,v 1.85 2013/02/13 02:05:40 jer Exp $
+
+*xfe-1.34 (13 Feb 2013)
+
+  13 Feb 2013; Jeroen Roovers <jer@gentoo.org> xfe-1.33-r1.ebuild,
+  +xfe-1.34.ebuild:
+  Version bump (bug #457030 by teidakankan). Do not install useless NEWS.
 
   28 Dec 2012; Agostino Sarubbo <ago@gentoo.org> xfe-1.33.ebuild:
   Stable for ppc64, wrt bug #448544
diff --git a/x11-misc/xfe/xfe-1.33-r1.ebuild b/x11-misc/xfe/xfe-1.33-r1.ebuild
index 07d5e309aad1..1bd11a3319b7 100644
--- a/x11-misc/xfe/xfe-1.33-r1.ebuild
+++ b/x11-misc/xfe/xfe-1.33-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xfe/xfe-1.33-r1.ebuild,v 1.1 2012/12/25 22:28:55 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xfe/xfe-1.33-r1.ebuild,v 1.2 2013/02/13 02:05:40 jer Exp $
 
 EAPI=5
 
@@ -35,7 +35,7 @@ DEPEND="
 	)
 "
 
-DOCS=( AUTHORS BUGS ChangeLog NEWS README TODO )
+DOCS=( AUTHORS BUGS ChangeLog README TODO )
 PATCHES=(
 	"${FILESDIR}"/${PN}-1.32.2-missing_Xlib_h.patch
 	"${FILESDIR}"/${P}-flags.patch
diff --git a/x11-misc/xfe/xfe-1.34.ebuild b/x11-misc/xfe/xfe-1.34.ebuild
new file mode 100644
index 000000000000..59024350c453
--- /dev/null
+++ b/x11-misc/xfe/xfe-1.34.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xfe/xfe-1.34.ebuild,v 1.1 2013/02/13 02:05:40 jer Exp $
+
+EAPI=5
+
+PLOCALES="
+	bs ca cs da de el es_AR es fr hu it ja nl no pl pt_BR pt_PT ru sv tr zh_CN
+	zh_TW
+"
+inherit autotools base l10n
+
+DESCRIPTION="MS-Explorer-like minimalist file manager for X"
+HOMEPAGE="http://roland65.free.fr/xfe"
+SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug nls startup-notification"
+
+RDEPEND="
+	media-libs/libpng:0
+	x11-libs/fox:1.6[truetype,png]
+	x11-libs/libX11
+	x11-libs/libXft
+	startup-notification? ( x11-libs/startup-notification )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+"
+
+DOCS=( AUTHORS BUGS ChangeLog README TODO )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.32.2-missing_Xlib_h.patch
+)
+
+src_prepare() {
+	base_src_prepare
+	cat >po/POTFILES.skip <<-EOF
+	src/icons.cpp
+	xfe.desktop.in.in
+	xfi.desktop.in.in
+	xfp.desktop.in.in
+	xfv.desktop.in.in
+	xfw.desktop.in.in
+	EOF
+
+	# malformed LINGUAS file
+	# recent intltool expects newline for every linguas
+	sed -i \
+		-e '/^#/!s:\s\s*:\n:g' \
+		po/LINGUAS || die
+
+	# remove not selected locales
+	rm_locale() { sed -i -e "/${1}/d" po/LINGUAS || die ;}
+	l10n_for_each_disabled_locale_do rm_locale
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-minimalflags \
+		$(use_enable nls) \
+		$(use_enable startup-notification sn) \
+		$(use_enable debug)
+}