Version bump. Some ebuild cleanup.

(Portage version: 2.1.7.15/cvs/Linux x86_64)

2 files changed, 79 insertions, 1 deletions

diff --git a/x11-plugins/purple-plugin_pack/ChangeLog b/x11-plugins/purple-plugin_pack/ChangeLog
index db313930857a..2f2fac5c6a30 100644
--- a/x11-plugins/purple-plugin_pack/ChangeLog
+++ b/x11-plugins/purple-plugin_pack/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-plugins/purple-plugin_pack
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-plugins/purple-plugin_pack/ChangeLog,v 1.25 2009/09/29 14:54:58 tester Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-plugins/purple-plugin_pack/ChangeLog,v 1.26 2009/12/21 20:53:01 pva Exp $
+
+*purple-plugin_pack-2.6.1 (21 Dec 2009)
+
+  21 Dec 2009; Peter Volkov <pva@gentoo.org>
+  +purple-plugin_pack-2.6.1.ebuild:
+  Version bump. Some ebuild cleanup.
 
   29 Sep 2009; Olivier Crête <tester@gentoo.org>
   -purple-plugin_pack-2.2.0.ebuild, -purple-plugin_pack-2.3.0.ebuild,
diff --git a/x11-plugins/purple-plugin_pack/purple-plugin_pack-2.6.1.ebuild b/x11-plugins/purple-plugin_pack/purple-plugin_pack-2.6.1.ebuild
new file mode 100644
index 000000000000..7dea04eefa31
--- /dev/null
+++ b/x11-plugins/purple-plugin_pack/purple-plugin_pack-2.6.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-plugins/purple-plugin_pack/purple-plugin_pack-2.6.1.ebuild,v 1.1 2009/12/21 20:53:01 pva Exp $
+
+EAPI="2"
+
+inherit eutils autotools
+
+DESCRIPTION="A package with many different plugins for pidgin and libpurple"
+HOMEPAGE="http://plugins.guifications.org"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~x86"
+IUSE="debug gtk ncurses spell talkfilters"
+
+RDEPEND="net-im/pidgin[gtk?,ncurses?]
+	talkfilters? ( app-text/talkfilters )
+	spell? ( app-text/gtkspell )"
+DEPEND="${RDEPEND}
+	dev-lang/python"
+
+src_prepare() {
+	# http://plugins.guifications.org/trac/ticket/597 
+	sed -e '/DEPENDENCIES=/{s:talkfilters:talkfiltersbin:}' \
+		-i configure* || die 
+	sed -e '/^depends/{s:$: talkfiltersbin:}' \
+		-i talkfilters/plugins.cfg || die
+	eautoreconf #Avoid maintainer mode
+}
+
+list_plugins_dep() {
+	local dependency=${1}
+	grep -EH "depends.*$dependency" */plugins.cfg | sed 's:/.*::'
+}
+
+src_configure() {
+	local plugins=""
+
+	# list all plugins, then pull DISABLED_PLUGINS with the ones we don't need
+	plugins="$(python plugin_pack.py -d dist_dirs)"
+
+	eval DISABLED_PLUGINS="\$${PN//[^a-z]/_}_DISABLED_PLUGINS"
+	# disable known broken plugins
+	DISABLED_PLUGINS+=" schedule findip"
+	use gtk || DISABLED_PLUGINS+=" $(list_plugins_dep pidgin)"
+	use ncurses || DISABLED_PLUGINS+=" $(list_plugins_dep finch)"
+	use spell || DISABLED_PLUGINS+=" $(list_plugins_dep gtkspell)"
+	use talkfilters || DISABLED_PLUGINS+=" $(list_plugins_dep talkfiltersbin)"
+
+	for plug in ${DISABLED_PLUGINS}; do
+		plugins="${plugins//${plug}}"
+	done
+
+	plugins="$(echo ${plugins} | sed 's:[ \t]\+:,:g;s:,$::;s:^,::')"
+
+	econf \
+		--with-plugins="${plugins}" \
+		$(use_enable debug)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog NEWS README VERSION || die
+}
+
+pkg_preinst() {
+	elog "Note: if you want to disable some plugins in pack, define"
+	elog "${PN//[^a-z]/_}_DISABLED_PLUGINS with a list of plugins to"
+	elog "skip during install."
+}