Add svg useflag and missing dep. Multiple other fixes. bug #481922

(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key C2BA7F3C!)

4 files changed, 168 insertions, 28 deletions

diff --git a/x11-wm/openbox/ChangeLog b/x11-wm/openbox/ChangeLog
index dadce9f706cb..696088c536c2 100644
--- a/x11-wm/openbox/ChangeLog
+++ b/x11-wm/openbox/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for x11-wm/openbox
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/ChangeLog,v 1.277 2013/08/17 11:56:13 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/ChangeLog,v 1.278 2013/08/24 23:35:40 hwoarang Exp $
+
+*openbox-3.5.2-r1 (24 Aug 2013)
+
+  24 Aug 2013; Markos Chandras <hwoarang@gentoo.org> +openbox-3.5.2-r1.ebuild,
+  openbox-9999.ebuild, metadata.xml:
+  Add missing useflag and dependency to librsvg. Rework ebuild and migrate
+  to python-r1. Rename xdg->python. Sync 9999 ebuild and use a common
+  ebuild for releases and git versions. Thanks to Julian Ospald
+  <hasufell@gentoo.org> for the fixes on bug #481962
 
   17 Aug 2013; Markos Chandras <hwoarang@gentoo.org>
   -openbox-3.5.0_p20111019.ebuild, -openbox-3.5.0_p20121006.ebuild:
diff --git a/x11-wm/openbox/metadata.xml b/x11-wm/openbox/metadata.xml
index 0c1b87464354..c0f3931eb2db 100644
--- a/x11-wm/openbox/metadata.xml
+++ b/x11-wm/openbox/metadata.xml
@@ -9,7 +9,8 @@
   </maintainer>
   <use>
  	 <flag name="session">Enables support for session managers</flag>
-	 <flag name="python">Install the python xdg files for xdg autostart</flag>
+	 <flag name="python">Install the python xdg files for xdg autostart(for compatibility with old ebuilds)</flag>
+	 <flag name="xdg">Install the python xdg files for xdg autostart</flag>
   </use>
   <upstream>
     <maintainer status='active'>
diff --git a/x11-wm/openbox/openbox-3.5.2-r1.ebuild b/x11-wm/openbox/openbox-3.5.2-r1.ebuild
new file mode 100644
index 000000000000..31df8319c72e
--- /dev/null
+++ b/x11-wm/openbox/openbox-3.5.2-r1.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/openbox-3.5.2-r1.ebuild,v 1.1 2013/08/24 23:35:40 hwoarang Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_6 python2_7 )
+inherit multilib autotools python-r1 eutils
+
+DESCRIPTION="A standards compliant, fast, light-weight, extensible window manager"
+HOMEPAGE="http://openbox.org/"
+if [[ ${PV} == *9999* ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://git.openbox.org/dana/openbox"
+	SRC_URI="branding? (
+	http://dev.gentoo.org/~hwoarang/distfiles/surreal-gentoo.tar.gz )"
+	KEYWORDS=""
+
+else
+	SRC_URI="http://openbox.org/dist/openbox/${P}.tar.gz
+	branding? ( http://dev.gentoo.org/~hwoarang/distfiles/surreal-gentoo.tar.gz )"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~arm-linux ~x86-linux"
+fi
+
+LICENSE="GPL-2"
+SLOT="3"
+IUSE="branding debug imlib nls session startup-notification static-libs svg xdg"
+REQUIRED_USE="xdg? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="dev-libs/glib:2
+	>=dev-libs/libxml2-2.0
+	>=media-libs/fontconfig-2
+	x11-libs/libXft
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libXt
+	>=x11-libs/pango-1.8[X]
+	imlib? ( media-libs/imlib2 )
+	startup-notification? ( >=x11-libs/startup-notification-0.8 )
+	svg? ( gnome-base/librsvg:2 )
+	xdg? (
+		${PYTHON_DEPS}
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+	)
+	"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	x11-proto/xextproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xineramaproto"
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]]; then
+		git-2_src_unpack
+	else
+		unpack ${A}
+	fi
+}
+
+src_prepare() {
+	use xdg && python_export_best
+	epatch "${FILESDIR}"/${PN}-3.5.2-gnome-session.patch
+	sed -i \
+		-e "s:-O0 -ggdb ::" \
+		-e 's/-fno-strict-aliasing//' \
+		"${S}"/m4/openbox.m4 || die
+	epatch_user
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_enable debug) \
+		$(use_enable static-libs static) \
+		$(use_enable nls) \
+		$(use_enable imlib imlib2) \
+		$(use_enable svg librsvg) \
+		$(use_enable startup-notification) \
+		$(use_enable session session-management) \
+		--with-x
+}
+
+src_install() {
+	dodir /etc/X11/Sessions
+	echo "/usr/bin/openbox-session" > "${ED}/etc/X11/Sessions/${PN}"
+	fperms a+x /etc/X11/Sessions/${PN}
+	emake DESTDIR="${D}" install
+	if use branding; then
+		insinto /usr/share/themes
+		doins -r "${WORKDIR}"/Surreal_Gentoo
+		# make it the default theme
+		sed -i \
+			-e "/<theme>/{n; s@<name>.*</name>@<name>Surreal_Gentoo</name>@}" \
+			"${D}"/etc/xdg/openbox/rc.xml \
+			|| die "failed to set Surreal Gentoo as the default theme"
+	fi
+	use static-libs || prune_libtool_files --all
+	if use xdg ; then
+		python_replicate_script "${ED}"/usr/libexec/openbox-xdg-autostart
+	else
+		rm "${ED}"/usr/libexec/openbox-xdg-autostart || die
+	fi
+}
diff --git a/x11-wm/openbox/openbox-9999.ebuild b/x11-wm/openbox/openbox-9999.ebuild
index eaadb181d5a6..6a510b297d32 100644
--- a/x11-wm/openbox/openbox-9999.ebuild
+++ b/x11-wm/openbox/openbox-9999.ebuild
@@ -1,80 +1,105 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/openbox-9999.ebuild,v 1.23 2013/08/14 18:05:31 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/openbox-9999.ebuild,v 1.24 2013/08/24 23:35:40 hwoarang Exp $
 
-EAPI="2"
-inherit multilib autotools eutils python git-2
+EAPI="5"
+
+PYTHON_COMPAT=( python2_6 python2_7 )
+inherit multilib autotools python-r1 eutils
 
 DESCRIPTION="A standards compliant, fast, light-weight, extensible window manager"
 HOMEPAGE="http://openbox.org/"
-SRC_URI="branding? (
-http://dev.gentoo.org/~hwoarang/distfiles/surreal-gentoo.tar.gz )"
-EGIT_REPO_URI="git://git.openbox.org/dana/openbox"
+if [[ ${PV} == *9999* ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://git.openbox.org/dana/openbox"
+	SRC_URI="branding? (
+	http://dev.gentoo.org/~hwoarang/distfiles/surreal-gentoo.tar.gz )"
+	KEYWORDS=""
+
+else
+	SRC_URI="http://openbox.org/dist/openbox/${P}.tar.gz
+	branding? ( http://dev.gentoo.org/~hwoarang/distfiles/surreal-gentoo.tar.gz )"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~arm-linux ~x86-linux"
+fi
 
 LICENSE="GPL-2"
 SLOT="3"
-KEYWORDS=""
-IUSE="branding debug imlib nls python session startup-notification static-libs"
+IUSE="branding debug imlib nls session startup-notification static-libs svg xdg"
+REQUIRED_USE="xdg? ( ${PYTHON_REQUIRED_USE} )"
 
 RDEPEND="dev-libs/glib:2
 	>=dev-libs/libxml2-2.0
-	python? ( dev-python/pyxdg )
 	>=media-libs/fontconfig-2
 	x11-libs/libXft
+	x11-libs/libXinerama
 	x11-libs/libXrandr
 	x11-libs/libXt
 	>=x11-libs/pango-1.8[X]
 	imlib? ( media-libs/imlib2 )
 	startup-notification? ( >=x11-libs/startup-notification-0.8 )
-	x11-libs/libXinerama"
+	svg? ( gnome-base/librsvg:2 )
+	xdg? (
+		${PYTHON_DEPS}
+		dev-python/pyxdg[${PYTHON_USEDEP}]
+	)
+	"
 DEPEND="${RDEPEND}
 	sys-devel/gettext
-	app-text/docbook2X
 	virtual/pkgconfig
 	x11-proto/xextproto
 	x11-proto/xf86vidmodeproto
 	x11-proto/xineramaproto"
 
+src_unpack() {
+	if [[ ${PV} == *9999* ]]; then
+		git-2_src_unpack
+	else
+		unpack ${A}
+	fi
+}
+
 src_prepare() {
-	use python && python_convert_shebangs -r 2 .
-	epatch "${FILESDIR}"/${P}-gnome-session.patch
-	# Lets try to replace docbook-to-man with docbook2man.pl since
-	# Gentoo does not provide (why?) a docbook-to-man package
-	sed -i -e "s:docbook-to-man:docbook2man.pl:" "${S}"/Makefile.am
+	use xdg && python_export_best
+	epatch "${FILESDIR}"/${PN}-3.5.2-gnome-session.patch
 	sed -i \
+		-e "s:-O0 -ggdb ::" \
 		-e 's/-fno-strict-aliasing//' \
-		m4/openbox.m4 || die
+		"${S}"/m4/openbox.m4 || die
 	epatch_user
 	eautoreconf
 }
 
 src_configure() {
 	econf \
-		--disable-silent-rules \
-		--docdir=/usr/share/doc/${PF} \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
 		$(use_enable debug) \
-		$(use_enable imlib imlib2) \
+		$(use_enable static-libs static) \
 		$(use_enable nls) \
+		$(use_enable imlib imlib2) \
+		$(use_enable svg librsvg) \
 		$(use_enable startup-notification) \
 		$(use_enable session session-management) \
-		$(use_enable static-libs static) \
 		--with-x
 }
 
 src_install() {
 	dodir /etc/X11/Sessions
-	echo "/usr/bin/openbox-session" > "${D}/etc/X11/Sessions/${PN}"
+	echo "/usr/bin/openbox-session" > "${ED}/etc/X11/Sessions/${PN}"
 	fperms a+x /etc/X11/Sessions/${PN}
-	emake DESTDIR="${D}" install || die "emake install failed"
+	emake DESTDIR="${D}" install
 	if use branding; then
 		insinto /usr/share/themes
 		doins -r "${WORKDIR}"/Surreal_Gentoo
 		# make it the default theme
 		sed -i \
-			"/<theme>/{n; s@<name>.*</name>@<name>Surreal_Gentoo</name>@}" \
+			-e "/<theme>/{n; s@<name>.*</name>@<name>Surreal_Gentoo</name>@}" \
 			"${D}"/etc/xdg/openbox/rc.xml \
 			|| die "failed to set Surreal Gentoo as the default theme"
 	fi
-	! use static-libs && rm "${D}"/usr/$(get_libdir)/lib{obt,obrender}.la
-	! use python && rm "${D}"/usr/libexec/openbox-xdg-autostart
+	use static-libs || prune_libtool_files --all
+	if use xdg ; then
+		python_replicate_script "${ED}"/usr/libexec/openbox-xdg-autostart
+	else
+		rm "${ED}"/usr/libexec/openbox-xdg-autostart || die
+	fi
 }