Bug #449722 -> s/gkmessage/gxmessage/g. Also version bump now that v1.3.3 is released

(Portage version: 2.1.11.18/cvs/Linux x86_64)

4 files changed, 121 insertions, 8 deletions

diff --git a/x11-wm/fluxbox/ChangeLog b/x11-wm/fluxbox/ChangeLog
index a95807105b7d..eade097b3806 100644
--- a/x11-wm/fluxbox/ChangeLog
+++ b/x11-wm/fluxbox/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for x11-wm/fluxbox
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v 1.305 2012/08/30 09:56:44 ssuominen Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v 1.306 2013/01/08 21:32:50 lack Exp $
+
+*fluxbox-1.3.3 (08 Jan 2013)
+
+  08 Jan 2013; Jim Ramsay <jim_ramsay@gentoo.org> +fluxbox-1.3.3.ebuild,
+  fluxbox-1.3.2.ebuild, fluxbox-9999.ebuild:
+  Bug #449722 -> s/gkmessage/gxmessage/g.  Also version bump now that v1.3.3 is
+  released
 
   30 Aug 2012; Samuli Suominen <ssuominen@gentoo.org> fluxbox-1.3.2.ebuild,
   fluxbox-9999.ebuild:
diff --git a/x11-wm/fluxbox/fluxbox-1.3.2.ebuild b/x11-wm/fluxbox/fluxbox-1.3.2.ebuild
index 93dca6c0c895..c8985e85498e 100644
--- a/x11-wm/fluxbox/fluxbox-1.3.2.ebuild
+++ b/x11-wm/fluxbox/fluxbox-1.3.2.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-1.3.2.ebuild,v 1.9 2012/08/30 09:56:44 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-1.3.2.ebuild,v 1.10 2013/01/08 21:32:50 lack Exp $
 
 EAPI=4
 inherit eutils flag-o-matic toolchain-funcs prefix
@@ -17,7 +17,7 @@ RDEPEND="x11-libs/libXpm
 	x11-libs/libXext
 	x11-libs/libXft
 	x11-libs/libXrender
-	|| ( x11-misc/gkmessage x11-apps/xmessage )
+	|| ( x11-misc/gxmessage x11-apps/xmessage )
 	xinerama? ( x11-libs/libXinerama )
 	truetype? ( media-libs/freetype )
 	bidi? ( >=dev-libs/fribidi-0.19.2 )
diff --git a/x11-wm/fluxbox/fluxbox-1.3.3.ebuild b/x11-wm/fluxbox/fluxbox-1.3.3.ebuild
new file mode 100644
index 000000000000..a1577a399a54
--- /dev/null
+++ b/x11-wm/fluxbox/fluxbox-1.3.3.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-1.3.3.ebuild,v 1.1 2013/01/08 21:32:50 lack Exp $
+
+EAPI=4
+inherit eutils flag-o-matic toolchain-funcs prefix
+
+IUSE="nls xinerama bidi +truetype +imlib +slit +toolbar vim-syntax"
+
+DESCRIPTION="Fluxbox is an X11 window manager featuring tabs and an iconbar"
+
+SRC_URI="mirror://sourceforge/fluxbox/${P}.tar.lzma"
+HOMEPAGE="http://www.fluxbox.org"
+
+RDEPEND="x11-libs/libXpm
+	x11-libs/libXrandr
+	x11-libs/libXext
+	x11-libs/libXft
+	x11-libs/libXrender
+	|| ( x11-misc/gxmessage x11-apps/xmessage )
+	xinerama? ( x11-libs/libXinerama )
+	truetype? ( media-libs/freetype )
+	bidi? ( >=dev-libs/fribidi-0.19.2 )
+	imlib? ( >=media-libs/imlib2-1.2.0[X] )
+	vim-syntax? ( app-vim/fluxbox-syntax )
+	!!<x11-themes/fluxbox-styles-fluxmod-20040809-r1
+	!!<=x11-misc/fluxconf-0.9.9
+	!!<=x11-misc/fbdesk-1.2.1"
+DEPEND="bidi? ( virtual/pkgconfig )
+	nls? ( sys-devel/gettext )
+	x11-proto/xextproto
+	${RDEPEND}"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux"
+
+src_prepare() {
+	# We need to be able to include directories rather than just plain
+	# files in menu [include] items. This patch will allow us to do clever
+	# things with style ebuilds.
+	epatch "${FILESDIR}/gentoo_style_location-1.1.x.patch"
+	eprefixify util/fluxbox-generate_menu.in
+
+	epatch "${FILESDIR}"/osx-has-otool.patch
+
+	# Add in the Gentoo -r number to fluxbox -version output.
+	if [[ "${PR}" == "r0" ]] ; then
+		suffix="gentoo"
+	else
+		suffix="gentoo-${PR}"
+	fi
+	sed -i \
+		-e "s~\(__fluxbox_version .@VERSION@\)~\1-${suffix}~" \
+		version.h.in || die "version sed failed"
+}
+
+src_configure() {
+	use bidi && append-cppflags "$($(tc-getPKG_CONFIG) --cflags fribidi)"
+
+	econf \
+		$(use_enable nls) \
+		$(use_enable xinerama) \
+		$(use_enable truetype xft) \
+		$(use_enable imlib imlib2) \
+		$(use_enable bidi fribidi ) \
+		$(use_enable slit ) \
+		$(use_enable toolbar ) \
+		--sysconfdir="${EPREFIX}"/etc/X11/${PN} \
+		--with-style="${EPREFIX}"/usr/share/fluxbox/styles/Emerge \
+		${myconf}
+}
+
+src_compile() {
+	default
+
+	ebegin "Creating a menu file (may take a while)"
+	mkdir -p "${T}/home/.fluxbox" || die "mkdir home failed"
+	MENUFILENAME="${S}/data/menu" MENUTITLE="Fluxbox ${PV}" \
+		CHECKINIT="no. go away." HOME="${T}/home" \
+		"${S}/util/fluxbox-generate_menu" -is -ds \
+		|| die "menu generation failed"
+	eend $?
+}
+
+src_install() {
+	dodir /usr/share/fluxbox
+	emake DESTDIR="${D}" STRIP="" install
+	dodoc README* AUTHORS TODO* ChangeLog NEWS
+
+	dodir /usr/share/xsessions
+	insinto /usr/share/xsessions
+	doins "${FILESDIR}/${PN}.desktop"
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}/${PN}.xsession" fluxbox
+
+	dodir /usr/share/fluxbox/menu.d
+
+	# Styles menu framework
+	dodir /usr/share/fluxbox/menu.d/styles
+	insinto /usr/share/fluxbox/menu.d/styles
+	doins "${FILESDIR}/styles-menu-fluxbox"
+	doins "${FILESDIR}/styles-menu-commonbox"
+	doins "${FILESDIR}/styles-menu-user"
+}
diff --git a/x11-wm/fluxbox/fluxbox-9999.ebuild b/x11-wm/fluxbox/fluxbox-9999.ebuild
index b2adea488f89..e249d2a60c9c 100644
--- a/x11-wm/fluxbox/fluxbox-9999.ebuild
+++ b/x11-wm/fluxbox/fluxbox-9999.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-9999.ebuild,v 1.12 2012/08/30 10:01:23 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-9999.ebuild,v 1.13 2013/01/08 21:32:50 lack Exp $
 
 EAPI=4
 inherit eutils flag-o-matic toolchain-funcs git-2 prefix
@@ -18,7 +18,7 @@ RDEPEND="x11-libs/libXpm
 	x11-libs/libXext
 	x11-libs/libXft
 	x11-libs/libXrender
-	|| ( x11-misc/gkmessage x11-apps/xmessage )
+	|| ( x11-misc/gxmessage x11-apps/xmessage )
 	xinerama? ( x11-libs/libXinerama )
 	truetype? ( media-libs/freetype )
 	bidi? ( >=dev-libs/fribidi-0.19.2 )