Revbump, migrate to distutils-r1.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

3 files changed, 68 insertions, 21 deletions

diff --git a/x11-wm/qtile/ChangeLog b/x11-wm/qtile/ChangeLog
index ae3451c40a46..0380a995ea4b 100644
--- a/x11-wm/qtile/ChangeLog
+++ b/x11-wm/qtile/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/qtile
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/qtile/ChangeLog,v 1.1 2012/11/13 05:03:09 radhermit Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/qtile/ChangeLog,v 1.2 2013/01/12 06:07:09 radhermit Exp $
+
+*qtile-0.5-r1 (12 Jan 2013)
+
+  12 Jan 2013; Tim Harder <radhermit@gentoo.org> +qtile-0.5-r1.ebuild,
+  qtile-9999.ebuild:
+  Revbump, migrate to distutils-r1.
 
 *qtile-9999 (13 Nov 2012)
 *qtile-0.5 (13 Nov 2012)
diff --git a/x11-wm/qtile/qtile-0.5-r1.ebuild b/x11-wm/qtile/qtile-0.5-r1.ebuild
new file mode 100644
index 000000000000..938f9dc6d0ba
--- /dev/null
+++ b/x11-wm/qtile/qtile-0.5-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/qtile/qtile-0.5-r1.ebuild,v 1.1 2013/01/12 06:07:09 radhermit Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+
+inherit distutils-r1 vcs-snapshot virtualx
+
+DESCRIPTION="A full-featured, hackable tiling window manager written in Python"
+HOMEPAGE="http://qtile.org/"
+SRC_URI="https://github.com/qtile/qtile/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/pycairo-1.10.0-r3[xcb]
+	dev-python/pygtk:2
+	>=x11-libs/xpyb-1.3.1"
+DEPEND="doc? ( dev-python/sphinx )
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/python-xlib
+		x11-base/xorg-server[kdrive]
+	)"
+
+# tests fail due to xauth errors from python-xlib
+RESTRICT="test"
+
+DOCS="TODO.rst"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	VIRTUALX_COMMAND="nosetests" virtualmake
+}
+
+python_install_all() {
+	use doc && dohtml -r docs/_build/html/*
+
+	insinto /usr/share/xsessions
+	doins resources/qtile.desktop
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}"/${PN}-session ${PN}
+}
diff --git a/x11-wm/qtile/qtile-9999.ebuild b/x11-wm/qtile/qtile-9999.ebuild
index 1108acc1d020..0b9f655b02e0 100644
--- a/x11-wm/qtile/qtile-9999.ebuild
+++ b/x11-wm/qtile/qtile-9999.ebuild
@@ -1,16 +1,11 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/qtile/qtile-9999.ebuild,v 1.1 2012/11/13 05:03:09 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/qtile/qtile-9999.ebuild,v 1.2 2013/01/12 06:07:09 radhermit Exp $
 
 EAPI="5"
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
 
-PYTHON_DEPEND="2"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="3.*"
-PYTHON_MODNAME="libqtile"
-DISTUTILS_SRC_TEST="nosetests"
-
-inherit git-2 distutils virtualx
+inherit git-2 distutils-r1 virtualx
 
 EGIT_REPO_URI="git://github.com/qtile/qtile.git"
 
@@ -28,6 +23,7 @@ RDEPEND=">=dev-python/pycairo-1.10.0-r3[xcb]
 DEPEND="doc? ( dev-python/sphinx )
 	test? (
 		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
 		dev-python/python-xlib
 		x11-base/xorg-server[kdrive]
 	)"
@@ -37,21 +33,15 @@ RESTRICT="test"
 
 DOCS="TODO.rst"
 
-src_compile() {
-	distutils_src_compile
+python_compile_all() {
 	use doc && emake -C docs html
 }
 
-src_test() {
-	testing() {
-		VIRTUALX_COMMAND="nosetests"
-		PYTHONPATH="build-${PYTHON_ABI}/lib" virtualmake
-	}
-	python_execute_function testing
+python_test() {
+	VIRTUALX_COMMAND="nosetests" virtualmake
 }
 
-src_install() {
-	distutils_src_install
+python_install_all() {
 	use doc && dohtml -r docs/_build/html/*
 
 	insinto /usr/share/xsessions