1 files changed, 73 insertions, 0 deletions
diff --git a/app-shells/tcsh/tcsh-6.15-r2.ebuild b/app-shells/tcsh/tcsh-6.15-r2.ebuild
new file mode 100644
index 000000000000..d01c573e9a19
--- /dev/null
+++ b/app-shells/tcsh/tcsh-6.15-r2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-shells/tcsh/tcsh-6.15-r2.ebuild,v 1.1 2007/07/24 20:53:13 grobian Exp $
+
+inherit eutils
+
+CONFVER="1.5"
+
+MY_P="${P}.00"
+DESCRIPTION="Enhanced version of the Berkeley C shell (csh)"
+HOMEPAGE="http://www.tcsh.org/"
+SRC_URI="ftp://ftp.astron.com/pub/tcsh/${MY_P}.tar.gz
+	mirror://gentoo/tcsh-config-${CONFVER}.tar.bz2
+	http://www.gentoo.org/~grobian/distfiles/tcsh-config-${CONFVER}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="perl catalogs"
+
+DEPEND=">=sys-libs/ncurses-5.1
+	perl? ( dev-lang/perl )
+	!app-shells/csh" # bug #119703
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}/${MY_P/15/14}"-debian-dircolors.patch # bug #120792
+	epatch "${FILESDIR}"/${PN}-6.14-makefile.patch # bug #151951
+	epatch "${FILESDIR}"/${MY_P}-normalize-command-fix.patch # bug #183754
+
+	if use catalogs ; then
+		einfo "enabling NLS catalogs support..."
+		sed -i -e "s/#undef NLS_CATALOGS/#define NLS_CATALOGS/" \
+			config_f.h || die
+		eend $?
+	fi
+}
+
+src_compile() {
+	econf --prefix=/ || die "econf failed"
+	emake || die "compile problem"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install.man || die
+
+	if use perl ; then
+		perl tcsh.man2html tcsh.man || die
+		dohtml tcsh.html/*.html
+	fi
+
+	insinto /etc
+	doins \
+		"${WORKDIR}"/tcsh-config/csh.cshrc \
+		"${WORKDIR}"/tcsh-config/csh.login
+
+	dodoc FAQ Fixes NewThings Ported README WishList Y2K
+
+	# bug #119703: add csh -> tcsh symlink
+	dosym /bin/tcsh /bin/csh
+}
+
+pkg_postinst() {
+	elog "This revision of tcsh does use a completely revamped configuration"
+	elog "files system, which is based on the bash equivalents.  It should"
+	elog "fix issues for KDE users, and miscelaneous issues of environment"
+	elog "variables not set that should have, like EDITOR.  If you rely"
+	elog "on the /etc/csh.* files heavily, you may find your setup will be"
+	elog "broken now."
+}