1 files changed, 48 insertions, 0 deletions
diff --git a/dev-python/cheetah/cheetah-2.2.2.ebuild b/dev-python/cheetah/cheetah-2.2.2.ebuild
new file mode 100644
index 000000000000..6cf1e02e34d6
--- /dev/null
+++ b/dev-python/cheetah/cheetah-2.2.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cheetah/cheetah-2.2.2.ebuild,v 1.1 2009/09/16 04:45:27 arfrever Exp $
+
+EAPI="2"
+SUPPORT_PYTHON_ABIS="1"
+
+inherit distutils
+
+MY_PN="Cheetah"
+MY_P="${MY_PN}-${PV/_}"
+
+DESCRIPTION="Python-powered template engine and code generator."
+HOMEPAGE="http://www.cheetahtemplate.org/ http://rtyler.github.com/cheetah/"
+SRC_URI="http://pypi.python.org/packages/source/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="PSF-2.2"
+IUSE=""
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+
+RDEPEND="dev-python/markdown"
+DEPEND="${RDEPEND}
+	dev-python/setuptools"
+RESTRICT_PYTHON_ABIS="3.*"
+
+S="${WORKDIR}/${MY_P}"
+
+PYTHON_MODNAME="Cheetah"
+DOCS="CHANGES README TODO"
+
+src_test() {
+	# Disable broken tests.
+	sed \
+		-e "/Unicode/d" \
+		-e "s/if not sys.platform.startswith('java'):/if False:/" \
+		-i cheetah/Tests/Test.py || die "sed failed"
+
+	testing() {
+		PYTHONPATH="$(ls -d build-${PYTHON_ABI}/lib.*)" "$(PYTHON)" cheetah/Tests/Test.py
+	}
+	python_execute_function testing
+}
+
+src_install() {
+	distutils_src_install
+	rm -fr "${D}"usr/lib*/python*/site-packages/Cheetah/Tests
+}