1 files changed, 49 insertions, 0 deletions
diff --git a/dev-util/devhelp/devhelp-3.8.0.ebuild b/dev-util/devhelp/devhelp-3.8.0.ebuild
new file mode 100644
index 000000000000..7c36dd0478c9
--- /dev/null
+++ b/dev-util/devhelp/devhelp-3.8.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/devhelp/devhelp-3.8.0.ebuild,v 1.1 2013/03/28 17:00:11 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit gnome2 python-single-r1 toolchain-funcs
+
+DESCRIPTION="An API documentation browser for GNOME"
+HOMEPAGE="http://live.gnome.org/devhelp"
+
+LICENSE="GPL-2+"
+SLOT="0/3-1" # subslot = 3-(libdevhelp-3 soname version)
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="gedit"
+
+# FIXME: automagic python dependency
+COMMON_DEPEND=">=dev-libs/glib-2.32:2
+	>=x11-libs/gtk+-3.5.6:3
+	>=net-libs/webkit-gtk-1.10.0:3"
+RDEPEND="${COMMON_DEPEND}
+	gedit? (
+		${PYTHON_DEPS}
+		app-editors/gedit[introspection,python,${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		x11-libs/gtk+[introspection] )
+	gnome-base/gsettings-desktop-schemas"
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	>=sys-devel/gettext-0.17
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# ICC is crazy, silence warnings (bug #154010)
+	if [[ $(tc-getCC) == "icc" ]] ; then
+		G2CONF="${G2CONF} --with-compile-warnings=no"
+	fi
+
+	use gedit || sed -e '/SUBDIRS/ s/gedit-plugin//' -i misc/Makefile.{am,in} || die
+
+	gnome2_src_prepare
+}