1 files changed, 52 insertions, 0 deletions
diff --git a/media-libs/freeverb3/freeverb3-2.5.5-r1.ebuild b/media-libs/freeverb3/freeverb3-2.5.5-r1.ebuild
new file mode 100644
index 000000000000..ed0f87c7d029
--- /dev/null
+++ b/media-libs/freeverb3/freeverb3-2.5.5-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/freeverb3/freeverb3-2.5.5-r1.ebuild,v 1.1 2010/07/26 00:14:24 sping Exp $
+
+EAPI=2
+inherit base versionator
+
+MY_PV=$(replace_version_separator 3 '')
+
+DESCRIPTION="High Quality Reverb and Impulse Response Convolution library including XMMS/Audacious Effect plugins"
+HOMEPAGE="http://freeverb3.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="audacious jack plugdouble sse sse2 sse3 3dnow forcefpu"
+
+RDEPEND=">=sci-libs/fftw-3.0.1
+	audacious? ( >=media-sound/audacious-2.4_beta1
+		media-libs/libsndfile )
+	jack? ( media-sound/jack-audio-connection-kit
+		media-libs/libsndfile )"
+DEPEND=${RDEPEND}
+
+S="${WORKDIR}/${PN}-$(get_version_component_range 1-3)"
+
+PATCHES=( "${FILESDIR}"/${P}-audacious-2.4_beta1.patch )
+
+src_configure() {
+	use sse3 && elog 'SSE3 support is broken in 2.5.5, auto-disabling for now'
+
+	# NOTE: sse4 support not implemented, yet
+	econf \
+		--enable-release \
+		--disable-bmp \
+		--disable-pluginit \
+		$(use_enable audacious) \
+		$(use_enable jack) \
+		$(use_enable plugdouble) \
+		$(use_enable 3dnow) \
+		$(use_enable sse) \
+		$(use_enable sse2) \
+		--disable-sse3 \
+		$(use_enable forcefpu) \
+		|| die "econf failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc ChangeLog README || die 'dodoc failed'
+}