1 files changed, 76 insertions, 0 deletions
diff --git a/media-video/mkvtoolnix/mkvtoolnix-5.3.0.ebuild b/media-video/mkvtoolnix/mkvtoolnix-5.3.0.ebuild
new file mode 100644
index 000000000000..35543a052c04
--- /dev/null
+++ b/media-video/mkvtoolnix/mkvtoolnix-5.3.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-5.3.0.ebuild,v 1.1 2012/02/10 05:31:26 radhermit Exp $
+
+EAPI=4
+
+inherit wxwidgets
+
+DESCRIPTION="Tools to create, alter, and inspect Matroska files"
+HOMEPAGE="http://www.bunkus.org/videotools/mkvtoolnix"
+SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="bzip2 debug lzo pch qt4 wxwidgets"
+
+RDEPEND="
+	>=dev-libs/libebml-1.2.2
+	>=media-libs/libmatroska-1.3.0
+	>=dev-libs/boost-1.46.0
+	dev-libs/expat
+	media-libs/flac
+	media-libs/libogg
+	media-libs/libvorbis
+	sys-apps/file
+	>=sys-devel/gcc-4.6
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	lzo? ( dev-libs/lzo )
+	qt4? (
+		x11-libs/qt-core:4
+		x11-libs/qt-gui:4
+	)
+	wxwidgets? ( x11-libs/wxGTK:2.8[X] )
+"
+DEPEND="${RDEPEND}
+	dev-ruby/rake
+	dev-util/pkgconfig
+"
+
+src_configure() {
+	local myconf
+
+	use pch || myconf+=" --disable-precompiled-headers"
+
+	if use wxwidgets ; then
+		WX_GTK_VER="2.8"
+		need-wxwidgets unicode
+		myconf+=" --with-wx-config=${WX_CONFIG}"
+	fi
+
+	econf \
+		$(use_enable bzip2 bz2) \
+		$(use_enable debug) \
+		$(use_enable lzo) \
+		$(use_enable qt4 qt) \
+		$(use_enable wxwidgets) \
+		${myconf} \
+		--with-boost-regex=boost_regex \
+		--with-boost-filesystem=boost_filesystem \
+		--with-boost-system=boost_system \
+		--without-curl
+}
+
+src_compile() {
+	rake || die "rake failed"
+}
+
+src_install() {
+	# Don't run strip while installing stuff, leave to portage the job.
+	DESTDIR="${D}" rake install || die
+
+	dodoc AUTHORS ChangeLog README TODO
+	doman doc/man/*.1
+}