1 files changed, 54 insertions, 0 deletions
diff --git a/sys-libs/tevent/tevent-0.9.22.ebuild b/sys-libs/tevent/tevent-0.9.22.ebuild
new file mode 100644
index 000000000000..596188b5f834
--- /dev/null
+++ b/sys-libs/tevent/tevent-0.9.22.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/tevent/tevent-0.9.22.ebuild,v 1.1 2014/10/03 21:02:14 polynomial-c Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_{6,7} )
+
+inherit waf-utils multilib-minimal python-single-r1
+
+DESCRIPTION="Samba tevent library"
+HOMEPAGE="http://tevent.samba.org/"
+SRC_URI="http://samba.org/ftp/tevent/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~arm-linux ~x86-linux"
+IUSE="python"
+
+RDEPEND=">=sys-libs/talloc-2.1.0[python?,${MULTILIB_USEDEP}]
+	python? ( ${PYTHON_DEPS} )"
+
+DEPEND="${RDEPEND}
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	${PYTHON_DEPS}
+"
+# build system does not work with python3
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+WAF_BINARY="${S}/buildtools/bin/waf"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	waf-utils_src_configure \
+		$(multilib_native_usex python '' '--disable-python')
+}
+
+multilib_src_compile() {
+	# need to avoid parallel building, this looks like the sanest way with waf-utils/multiprocessing eclasses
+	unset MAKEOPTS
+	waf-utils_src_compile
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+
+	multilib_is_native_abi && use python && python_domodule tevent.py
+}