1 files changed, 85 insertions, 0 deletions
diff --git a/www-apps/drupal/drupal-7.23.ebuild b/www-apps/drupal/drupal-7.23.ebuild
new file mode 100644
index 000000000000..00ec7fef1a3a
--- /dev/null
+++ b/www-apps/drupal/drupal-7.23.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-apps/drupal/drupal-7.23.ebuild,v 1.1 2013/09/13 12:13:30 jmbsvicetto Exp $
+
+EAPI=5
+
+inherit webapp
+
+MY_PV=${PV:0:3}.0
+
+DESCRIPTION="PHP-based open-source platform and content management system"
+HOMEPAGE="http://drupal.org/"
+SRC_URI="http://drupal.org/files/projects/${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~ppc ~x86"
+IUSE="+accelerator +mysql postgres sqlite +uploadprogress"
+
+RDEPEND="
+	dev-lang/php[gd,pdo,postgres?,xml]
+	virtual/httpd-php
+	accelerator? ( ||
+		(
+			(
+				<dev-lang/php-5.5
+				dev-php/pecl-apc
+			)
+			dev-php/xcache
+			dev-php/eaccelerator
+			(
+				>=dev-lang/php-5.5[opcache]
+				dev-php/pecl-apcu
+			)
+		)
+	)
+	uploadprogress? ( dev-php/pecl-uploadprogress )
+	mysql? (
+		|| (
+			dev-lang/php[mysql]
+			dev-lang/php[mysqli]
+		)
+	)
+	sqlite? (
+		|| (
+			dev-lang/php[sqlite]
+			dev-lang/php[sqlite3]
+		)
+	)
+"
+
+need_httpd_cgi
+
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+src_install() {
+	webapp_src_preinst
+
+	local docs="MAINTAINERS.txt LICENSE.txt INSTALL.txt CHANGELOG.txt INSTALL.mysql.txt INSTALL.pgsql.txt INSTALL.sqlite.txt UPGRADE.txt "
+	dodoc ${docs}
+	rm -f ${docs} INSTALL COPYRIGHT.txt
+
+	cp sites/default/{default.settings.php,settings.php}
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	dodir "${MY_HTDOCSDIR}"/files
+	webapp_serverowned "${MY_HTDOCSDIR}"/files
+	webapp_serverowned "${MY_HTDOCSDIR}"/sites/default
+	webapp_serverowned "${MY_HTDOCSDIR}"/sites/default/settings.php
+
+	webapp_configfile "${MY_HTDOCSDIR}"/sites/default/settings.php
+	webapp_configfile "${MY_HTDOCSDIR}"/.htaccess
+
+	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
+
+	webapp_src_install
+}
+
+pkg_postinst() {
+	ewarn
+	ewarn "SECURITY NOTICE"
+	ewarn "If you plan on using SSL on your Drupal site, please consult the postinstall information:"
+	ewarn "\t# webapp-config --show-postinst ${PN} ${PV}"
+	ewarn
+}