1 files changed, 48 insertions, 0 deletions
diff --git a/x11-libs/flowcanvas/flowcanvas-0.6.0.ebuild b/x11-libs/flowcanvas/flowcanvas-0.6.0.ebuild
new file mode 100644
index 000000000000..c490fea2e38d
--- /dev/null
+++ b/x11-libs/flowcanvas/flowcanvas-0.6.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/flowcanvas/flowcanvas-0.6.0.ebuild,v 1.1 2009/12/12 18:22:03 aballier Exp $
+
+EAPI=2
+
+inherit toolchain-funcs multilib eutils
+
+DESCRIPTION="Gtkmm/Gnomecanvasmm widget for boxes and lines environments"
+HOMEPAGE="http://wiki.drobilla.net/FlowCanvas"
+SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc"
+
+RDEPEND="dev-libs/boost
+	>=dev-cpp/gtkmm-2.4
+	>=dev-cpp/libgnomecanvasmm-2.6
+	media-gfx/graphviz"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	epatch "${FILESDIR}/ldconfig.patch"
+}
+
+src_configure() {
+	tc-export CC CXX CPP AR RANLIB
+	./waf configure \
+		--prefix=/usr \
+		--libdir=/usr/$(get_libdir) \
+		--htmldir=/usr/share/doc/${PF}/html \
+		$(use debug && echo "--debug") \
+		$(use doc && echo "--build-docs") \
+		|| die
+}
+
+src_compile() {
+	./waf || die
+}
+
+src_install() {
+	./waf install --destdir="${D}" || die
+	dodoc AUTHORS README ChangeLog
+}