app-office/glabels/glabels-3.0.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/glabels/glabels-3.0.1-r1.ebuild,v 1.2 2013/04/07 10:49:28 eva Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit eutils gnome2

DESCRIPTION="Program for creating labels and business cards"
HOMEPAGE="http://www.glabels.org/"

LICENSE="GPL-2 FDL-1.1 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="barcode eds"

RDEPEND="
	>=dev-libs/glib-2.28.2:2
	>=x11-libs/gtk+-3.0.9:3
	>=dev-libs/libxml2-2.7.8:2
	>=gnome-base/librsvg-2.32.0:2
	>=x11-libs/cairo-1.10.0
	>=x11-libs/pango-1.28.1
	barcode? (
		>=app-text/barcode-0.98
		>=media-gfx/qrencode-3.1 )
	eds? ( >=gnome-extra/evolution-data-server-2.30.3 )
"
DEPEND="${RDEPEND}
	app-text/scrollkeeper
	app-text/gnome-doc-utils
	app-text/docbook-xml-dtd:4.1.2
	dev-util/gtk-doc-am
	>=dev-util/intltool-0.28
	virtual/pkgconfig
"

src_prepare() {
	# Fix desktop entry, upstream bug #684612
	sed -i -e 's/.png//' data/desktop/glabels-3.0.desktop.in || die
	sed -i -e '/Encoding/d' data/desktop/glabels-3.0.desktop.in || die

	# Fix building with eds-3.6 (from master)
	epatch "${FILESDIR}/${PN}-3.0.1-eds-3.6.patch"
}

src_configure() {
	gnome2_src_configure \
		$(use_with eds libebook) \
		--disable-static
}