dev-haskell/hsshellscript/hsshellscript-2.6.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-haskell/hsshellscript/hsshellscript-2.6.0.ebuild,v 1.2 2005/11/18 11:43:54 araujo Exp $

inherit base eutils ghc-package

DESCRIPTION="A Haskell library for UNIX shell scripting tasks"
HOMEPAGE="http://www.volker-wysk.de/hsshellscript/"
SRC_URI="http://www.volker-wysk.de/hsshellscript/dist/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND=">=virtual/ghc-6.4
	>=dev-haskell/haddock-0.6"
RDEPEND=""

src_unpack() {
	base_src_unpack
	cd ${S}
	sed -i -e "/ghc-pkg/d" Makefile
}

src_compile() {
	# Fix hsshellscript.cabal library path
	sed -i "s:@DEST_LIB:$(ghc-libdir):" \
	        ${S}/lib/hsshellscript.cabal
	sed -i "s:@DEST_IMPORTS:$(ghc-libdir)/imports:" \
			${S}/lib/hsshellscript.cabal
	emake || die "emake failed"
}

src_install() {
	# we register the .cabal file generated by make
	ghc-setup-pkg ${S}/build/hsshellscript.cabal
	make install \
		DESTDIR="${D}" \
		DEST_LIB="$(ghc-libdir)" \
		DEST_IMPORTS="$(ghc-libdir)/imports" \
		DEST_DOC="/usr/share/doc/${PF}" \
		|| die "make failed"
	ghc-makeghcilib ${D}/$(ghc-libdir)/libhsshellscript.a
	ghc-install-pkg
	fperms 0644 $(ghc-libdir)/imports/hsshellscript.h
}