dev-java/metadata-extractor/metadata-extractor-2.2.2-r4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/metadata-extractor/metadata-extractor-2.2.2-r4.ebuild,v 1.1 2014/01/02 15:22:51 tomwij Exp $

EAPI="5"

inherit java-pkg-2 java-ant-2 eutils

DESCRIPTION="Metadata extraction framework for Exif and IPTC metadata segments, extraction support for JPEG files"
HOMEPAGE="http://www.drewnoakes.com/code/exif/"
SRC_URI="http://www.drewnoakes.com/code/exif/metadata-extractor-${PV}-src.jar"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

IUSE="test"

DEPEND="|| ( =virtual/jdk-1.6* =virtual/jdk-1.5* =virtual/jdk-1.4* )
	test? ( dev-java/junit:0 )
	app-arch/unzip:0"

RDEPEND=">=virtual/jre-1.4"
S=${WORKDIR}

java_prepare() {
	epatch "${FILESDIR}"/${P}-buildfix.patch

	mv metadata-extractor.build build.xml || die

	use test && java-pkg_jar-from --build-only --into lib/ junit junit.jar
}

EANT_DOC_TARGET=""
EANT_BUILD_TARGET="dist-binaries"

src_install() {
	java-pkg_newjar dist/*.jar ${PN}.jar

	dodoc ReleaseNotes.txt
}

src_test() {
	ANT_TASKS="ant-junit" eant test
}