dev-libs/libhid/libhid-0.2.16-r4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libhid/libhid-0.2.16-r4.ebuild,v 1.1 2014/08/13 11:08:25 jer Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit autotools eutils python-single-r1

DESCRIPTION="Provides a generic and flexible way to access and interact with USB HID devices"
HOMEPAGE="http://libhid.alioth.debian.org/"
SRC_URI="http://beta.magicaltux.net/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="doc python static-libs"

RDEPEND="
	python? ( ${PYTHON_DEPS} )
	virtual/libusb:0
"
DEPEND="
	${RDEPEND}
	doc? ( app-doc/doxygen )
	python? ( dev-lang/swig )
"

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	epatch "${FILESDIR}"/${P}-swig.patch
	epatch "${FILESDIR}"/${P}-libusb.patch

	eautoreconf
}

src_configure() {
	export OS_LDFLAGS="${LDFLAGS}"
	use python && export PYTHON_LDFLAGS=$(${EPYTHON}-config --ldflags)

	econf \
		$(use_enable python swig) \
		$(use_enable static-libs static) \
		$(use_with doc doxygen) \
		--disable-debug \
		--disable-werror
}

DOCS=( AUTHORS ChangeLog NEWS README README.licence TODO )

src_install() {
	default

	use doc && dohtml -r doc/html/*

	prune_libtool_files
}