dev-python/epydoc/epydoc-3.0.1-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/epydoc/epydoc-3.0.1-r2.ebuild,v 1.2 2012/12/17 19:55:55 mgorny Exp $

EAPI=5
PYTHON_COMPAT=( python{2_5,2_6,2_7} )
PYTHON_REQ_USE='tk?'

inherit distutils-r1

DESCRIPTION="Tool for generating API documentation for Python modules from docstrings"
HOMEPAGE="http://epydoc.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="doc latex tk"

DEPEND=""
RDEPEND="dev-python/docutils[${PYTHON_USEDEP}]
	latex? ( virtual/latex-base
			 dev-texlive/texlive-latexextra
	)"

PATCHES=(
	"${FILESDIR}"/${PN}-docutils-0.6.patch
	"${FILESDIR}"/${PN}-python-2.6.patch
)

python_install() {
	distutils-r1_python_install

	use tk || rm "${D}$(python_get_sitedir)"/epydoc/gui.py*
}

python_install_all() {
	use doc && local HTML_DOCS=( doc/. )
	distutils-r1_python_install_all

	doman man/epydoc.1
	if use tk; then
		doman man/epydocgui.1
	else
		rm -f "${ED}"usr/bin/epydocgui*
	fi
}