dev-python/python-openid/python-openid-2.2.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/python-openid/python-openid-2.2.1.ebuild,v 1.1 2008/10/06 16:40:05 hawking Exp $

NEED_PYTHON=2.3

inherit distutils

DESCRIPTION="OpenID support for servers and consumers."
HOMEPAGE="http://www.openidenabled.com/openid/libraries/python/"
SRC_URI="http://www.openidenabled.com/files/${PN}/packages/${P}.tar.bz2"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples mysql postgres sqlite"

RDEPEND="|| ( >=dev-lang/python-2.5 dev-python/elementtree )
	|| ( >=dev-lang/python-2.5 dev-python/pycrypto )
	sqlite? (
		|| ( >=dev-lang/python-2.5 >=dev-python/pysqlite-2 )
	)
	postgres? ( dev-python/psycopg )
	mysql? ( >=dev-python/mysql-python-1.2.2 )"
DEPEND="${RDEPEND}"

PYTHON_MODNAME="openid"

src_unpack() {
	distutils_src_unpack

	# Patch to fix confusion with localhost/127.0.0.1
	epatch "${FILESDIR}"/${PN}-2.0.0-gentoo-test_fetchers.diff
}

src_install() {
	distutils_src_install

	use doc && dohtml doc/*

	if use examples ; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}

src_test() {
	#Remove test that requires running db server
	sed -e '/storetest/d' -i admin/runtests

	"${python}" admin/runtests || die "tests failed"
}