dev-util/aegis/aegis-4.19.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/aegis/aegis-4.19.ebuild,v 1.8 2008/06/30 01:43:53 darkside Exp $

IUSE="tk"

DESCRIPTION="A transaction based revision control system"
SRC_URI="mirror://sourceforge/aegis/${P}.tar.gz"
HOMEPAGE="http://aegis.sourceforge.net"

DEPEND="sys-libs/zlib
	sys-devel/gettext
	sys-apps/groff
	sys-devel/bison
	tk? ( >=dev-lang/tk-8.3 )"
RDEPEND="" #221421

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~alpha ~ppc sparc x86"

src_compile() {
	# By default aegis configure puts shareable read/write files (locks etc)
	# in ${prefix}/com/aegis but the FHS says /var/lib/aegis can be shared.

	econf \
		--sharedstatedir=/var/lib/aegis \
		--with-nlsdir=/usr/share/locale \
		|| die "./configure failed"

	# Second ebuild causes redefined/undefined function errors
	make clean

	# not emake safe, I think
	make || die
}

src_install () {
	make RPM_BUILD_ROOT="${D}" install || die

	# Alas gentoo appears to have no profile.d mechanism, so:
	rm "${D}"/etc/profile.d/aegis.sh
	rm "${D}"/etc/profile.d/aegis.csh
	rmdir "${D}"/etc/profile.d
	rmdir "${D}"/etc

	# OK so ${D}/var/lib/aegis gets UID=3, but for some
	# reason so do the files under /usr/share, even though
	# they are read-only.
	chown -R root:0 "${D}"/usr/share
	dodoc lib/en/*

	# Link to share dir so user has a chance of noticing it.
	dosym /usr/share/aegis /usr/share/doc/${PF}/scripts

	# Config file examples are documentation.
	mv "${D}"/usr/share/aegis/config.example "${D}"/usr/share/doc/${PF}/

	dodoc BUILDING MANIFEST README
}