games-emulation/atari800/atari800-2.0.3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/atari800/atari800-2.0.3.ebuild,v 1.1 2007/07/13 03:25:04 mr_bones_ Exp $

inherit games

DESCRIPTION="Atari 800 emulator"
HOMEPAGE="http://atari800.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
	mirror://sourceforge/${PN}/xf25.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE="sdl"

RDEPEND="sdl? ( >=media-libs/libsdl-1.2.0 )
	!sdl? ( x11-libs/libX11 )"
DEPEND="${RDEPEND}
	!sdl? (
		x11-libs/libXt
		x11-libs/libX11
		x11-proto/xextproto
		x11-proto/xproto )
	app-arch/unzip"

src_unpack() {
	unpack ${A}
	cd "${S}"
	# remove some not-so-interesting ones
	rm -f DOC/{INSTALL.*,*.in,CHANGES.OLD}
	sed -i \
		-e "/CFG_FILE/s:/etc:${GAMES_SYSCONFDIR}:" \
		src/atari.c \
		|| die "sed failed"
	sed -i \
		-e 's/LDFLAGS="-s"/:/' \
		src/configure \
		|| die "sed failed"
}

src_compile() {
	local target="x11"
	use sdl && target="sdl"

	cd src && \
	egamesconf \
		--enable-crashmenu \
		--enable-break \
		--enable-hints \
		--enable-asm \
		--enable-cursorblk \
		--enable-led \
		--enable-displayled \
		--enable-sndclip \
		--enable-linuxjoy \
		--enable-sound \
		--target=${target} \
		|| die
	emake || die "emake failed"
}

src_install () {
	dogamesbin src/atari800 || die "dogamesbin failed"
	newman src/atari800.man atari800.6
	dodoc README.1ST DOC/*
	insinto "${GAMES_DATADIR}/${PN}"
	doins "${WORKDIR}/"*.ROM || die "doins failed (ROM)"
	sed "s:/usr/share/games:${GAMES_DATADIR}:" \
		"${FILESDIR}"/atari800.cfg > "${T}"/atari800.cfg \
		|| die "sed failed"
	insinto "${GAMES_SYSCONFDIR}"
	doins "${T}"/atari800.cfg || die "doins failed (cfg)"
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	if use sdl ; then
		echo
		elog 'The emulator has been compiled using the SDL libraries.  By default,'
		elog 'atari800 switches to fullscreen mode, so a 400x300 entry in your'
		elog 'XF86Config-4 file is recommended.  Otherwise, the emulated Atari'
		elog 'screen is postage-stamp sized in the middle of your display.'
		echo
		elog 'For example, in the "Screen" section of your /etc/XF86Config-4 file,'
		elog 'add the entry "400x300" to the end of the list of modes:'
		echo
		elog '  Section "Screen"'
		elog '    [...]'
		elog
		elog '      Subsection "Display"'
		elog '          Depth       16'
		elog '          Modes       "1600x1200" "1024x768" "400x300"'
		elog '          ViewPort    0 0'
		elog '      EndSubsection'
		elog '  EndSection'
		echo
		elog 'You should not need to specify a modeline for this mode,'
		elog 'since in most cases it is a standard mode calculated by'
		elog 'the X server.'
		echo
	fi
}