games-rpg/daimonin-client/daimonin-client-0.9.7.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-rpg/daimonin-client/daimonin-client-0.9.7.1.ebuild,v 1.3 2010/01/08 01:12:47 josejx Exp $

EAPI=2
inherit eutils games

MY_P=${PN/-/_}-${PV}
DESCRIPTION="a graphical 2D tile-based MMORPG"
HOMEPAGE="http://daimonin.sourceforge.net/"
SRC_URI="mirror://sourceforge/daimonin/${MY_P}.zip
	mirror://sourceforge/daimonin/AllMusic.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-amd64 ppc x86"
IUSE=""

RDEPEND="media-libs/libsdl
	media-libs/sdl-mixer[vorbis]
	media-libs/sdl-image[png]
	dev-games/physfs
	net-misc/curl"
DEPEND="${RDEPEND}
	app-arch/unzip"

S=${WORKDIR}/daimonin/client/make/linux

src_unpack() {
	unpack ${MY_P}.zip
	cd daimonin/client/media
	rm -f *
	unpack AllMusic.zip
}

src_prepare() {
	sed -i \
		-e 's:$(d_datadir):$(DESTDIR)$(d_datadir):' \
		-e '/PROGRAMS/s:daimonin-updater::' \
		-e '/\/tools/d' \
		Makefile.in \
		|| die "sed failed"
	chmod +x configure
}

src_configure() {
	egamesconf --disable-simplelayout
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	cd ../..
	dodoc README*
	newicon skins/subred/bitmaps/pentagram.png ${PN}.png || die "newicon failed"
	make_desktop_entry daimonin Daimonin
	prepgamesdirs
}