blob: bfcbdd01af744cd250e189976e8a7ab4d23b9a9e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-settings-daemon/gnome-settings-daemon-3.8.6.1.ebuild,v 1.6 2013/12/27 20:52:13 pacho Exp $
EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
inherit autotools eutils gnome2 systemd virtualx
DESCRIPTION="Gnome Settings Daemon"
HOMEPAGE="https://git.gnome.org/browse/gnome-settings-daemon"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
# smartcard support is disabled for 3.8.x, bug #491592
IUSE="+colord +cups debug +i18n input_devices_wacom -openrc-force packagekit policykit +short-touchpad-timeout +udev" #smartcard
REQUIRED_USE="
packagekit? ( udev )
"
# smartcard? ( udev )
# require colord-0.1.27 dependency for connection type support
COMMON_DEPEND="
>=dev-libs/glib-2.35.3:2
>=x11-libs/gtk+-3.7.8:3
>=gnome-base/gnome-desktop-3.7.90:3=
>=gnome-base/gsettings-desktop-schemas-3.7.2.1
>=gnome-base/librsvg-2.36.2
media-fonts/cantarell
media-libs/fontconfig
>=media-libs/lcms-2.2:2
media-libs/libcanberra[gtk3]
>=media-sound/pulseaudio-2
>=sys-power/upower-0.9.11
x11-libs/cairo
x11-libs/gdk-pixbuf:2
>=x11-libs/libnotify-0.7.3:=
x11-libs/libX11
x11-libs/libxkbfile
x11-libs/libXi
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXtst
x11-libs/libXxf86misc
colord? ( >=x11-misc/colord-0.1.27:= )
cups? ( >=net-print/cups-1.4[dbus] )
i18n? ( >=app-i18n/ibus-1.4.99 )
input_devices_wacom? (
>=dev-libs/libwacom-0.7
x11-drivers/xf86-input-wacom )
packagekit? ( >=app-admin/packagekit-base-0.7.4 )
udev? ( virtual/udev[gudev] )
"
# smartcard? ( >=dev-libs/nss-3.11.2 )
# Themes needed by g-s-d, gnome-shell, gtk+:3 apps to work properly
# <gnome-color-manager-3.1.1 has file collisions with g-s-d-3.1.x
# <gnome-power-manager-3.1.3 has file collisions with g-s-d-3.1.x
# systemd needed for power and session management, bug #464944
RDEPEND="${COMMON_DEPEND}
gnome-base/dconf
!openrc-force? ( sys-apps/systemd )
>=x11-themes/gnome-themes-standard-2.91
>=x11-themes/gnome-icon-theme-2.91
>=x11-themes/gnome-icon-theme-symbolic-2.91
!<gnome-base/gnome-control-center-2.22
!<gnome-extra/gnome-color-manager-3.1.1
!<gnome-extra/gnome-power-manager-3.1.3
"
# xproto-7.0.15 needed for power plugin
DEPEND="${COMMON_DEPEND}
cups? ( sys-apps/sed )
dev-libs/libxml2:2
sys-devel/gettext
>=dev-util/intltool-0.40
virtual/pkgconfig
x11-proto/inputproto
x11-proto/xf86miscproto
>=x11-proto/xproto-7.0.15
"
src_prepare() {
# https://bugzilla.gnome.org/show_bug.cgi?id=621836
# Apparently this change severely affects touchpad usability for some
# people, so revert it if USE=short-touchpad-timeout.
# Revisit if/when upstream adds a setting for customizing the timeout.
use short-touchpad-timeout &&
epatch "${FILESDIR}/${PN}-3.7.90-short-touchpad-timeout.patch"
# Make colord and wacom optional; requires eautoreconf
epatch "${FILESDIR}/${PN}-3.7.90-optional-color-wacom.patch"
epatch_user
eautoreconf
gnome2_src_prepare
}
src_configure() {
gnome2_src_configure \
--disable-static \
--enable-man \
$(use_enable colord color) \
$(use_enable cups) \
$(use_enable debug) \
$(use_enable debug more-warnings) \
$(use_enable i18n ibus) \
$(use_enable packagekit) \
--disable-smartcard-support \
$(use_enable udev gudev) \
$(use_enable input_devices_wacom wacom)
# $(use_enable smartcard smartcard-support) \
}
src_test() {
Xemake check
}
pkg_postinst() {
gnome2_pkg_postinst
if ! systemd_is_booted; then
ewarn "${PN} needs Systemd to be *running* for working"
ewarn "properly. Please follow the this guide to migrate:"
ewarn "http://wiki.gentoo.org/wiki/Systemd"
fi
if use openrc-force; then
ewarn "You are enabling 'openrc-force' USE flag to skip systemd requirement,"
ewarn "this can lead to unexpected problems and is not supported neither by"
ewarn "upstream neither by Gnome Gentoo maintainers. If you suffer any problem,"
ewarn "you will need to disable this USE flag system wide and retest before"
ewarn "opening any bug report."
fi
}
|
GitWeb